Arduino RS422 vers WiFi
Dans ce guide, nous allons explorer l'utilisation de l'Arduino Uno R4 WiFi pour construire un convertisseur série RS422 vers WiFi. Avec cette configuration, l'Arduino lira les données depuis une interface série RS422 et les transmettra à un serveur TCP, soit au sein du même réseau local (LAN), soit à distance via internet. Il peut également recevoir des données du serveur TCP et les renvoyer via l'interface série RS422.
Ces étapes vous permettront d'établir des ponts de communication polyvalents entre des appareils série RS-422 et un serveur TCP/IP en utilisant Arduino.
Préparation du matériel
Or you can buy the following sensor kits:
| 1 | × | DIYables Sensor Kit (30 sensors/displays) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgation : Certains des liens fournis dans cette section sont des liens affiliés Amazon. Nous pouvons recevoir une commission pour tout achat effectué via ces liens, sans coût supplémentaire pour vous. Nous vous remercions de votre soutien.
À propos de RS422 et TCP
Si vous ne savez pas comment utiliser la communication RS422 et TCP avec Arduino, renseignez-vous dans les tutoriels suivants :
- Arduino - RS422 tutorial
- Arduino - TCP Client tutorial
Fonctionnement du convertisseur RS422 vers WiFi
- Arduino se connecte à un appareil série via l'interface série RS422
- Arduino fonctionne comme un client TCP qui se connecte à un serveur TCP (peut être un logiciel serveur TCP sur votre PC ou un autre Arduino programmé comme serveur TCP)
- Arduino lit les données de l'interface série RS422 et les envoie au serveur TCP
- Arduino lit les données de la connexion TCP et les envoie à l'interface série RS422
Diagramme de câblage
- Schéma de câblage si utilisation d'une liaison série matérielle
This image is created using Fritzing. Click to enlarge image
- Schéma de câblage si utilisation d'une liaison série logicielle
This image is created using Fritzing. Click to enlarge image
Code Arduino pour le port série matériel
/*
* Ce code Arduino a été développé par newbiely.fr
* Ce code Arduino est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino/arduino-rs422-to-wifi
*/
#include <WiFiS3.h>
const char* WIFI_SSID = "YOUR_WIFI_SSID"; // CHANGE TO YOUR WIFI SSID
const char* WIFI_PASSWORD = "YOUR_WIFI_PASSWORD"; // CHANGE TO YOUR WIFI PASSWORD
const char* TCP_SERVER_ADDR = "192.168.0.26"; // CHANGE TO TCP SERVER'S IP ADDRESS
const int TCP_SERVER_PORT = 1470;
WiFiClient TCP_client;
void setup() {
Serial.begin(9600);
Serial.println("Arduino: TCP CLIENT");
// check for the WiFi module:
if (WiFi.status() == WL_NO_MODULE) {
Serial.println("Communication with WiFi module failed!");
// don't continue
while (true)
;
}
String fv = WiFi.firmwareVersion();
if (fv < WIFI_FIRMWARE_LATEST_VERSION) {
Serial.println("Please upgrade the firmware");
}
Serial.print("Attempting to connect to SSID: ");
Serial.println(WIFI_SSID);
// attempt to connect to WiFi network:
while (WiFi.begin(WIFI_SSID, WIFI_PASSWORD) != WL_CONNECTED) {
delay(10000); // wait 10 seconds for connection:
}
Serial.print("Connected to WiFi ");
Serial.println(WIFI_SSID);
// connect to TCP server
if (TCP_client.connect(TCP_SERVER_ADDR, TCP_SERVER_PORT))
Serial.println("Connected to TCP server");
else
Serial.println("Failed to connect to TCP server");
}
void loop() {
if (TCP_client.connected()) {
// read data from TCP and send them to RS422 interface
if (TCP_client.available()) {
char c = TCP_client.read();
Serial.write(c);
}
// read data from RS422 interface and send them to TCP
if (Serial.available()) {
char c = Serial.read();
TCP_client.write(c);
}
} else {
Serial.println("Connection is disconnected");
TCP_client.stop();
// reconnect to TCP server
if (TCP_client.connect(TCP_SERVER_ADDR, TCP_SERVER_PORT)) {
Serial.println("Reconnected to TCP server");
} else {
Serial.println("Failed to reconnect to TCP server");
delay(1000);
}
}
}
Code Arduino pour le port série logiciel
/*
* Ce code Arduino a été développé par newbiely.fr
* Ce code Arduino est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino/arduino-rs422-to-wifi
*/
#include <WiFiS3.h>
#include <SoftwareSerial.h>
// define the SoftwareSerial object and their pins
SoftwareSerial rs422(6, 7); // RX: 6, TX: 7
const char* WIFI_SSID = "YOUR_WIFI_SSID"; // CHANGE TO YOUR WIFI SSID
const char* WIFI_PASSWORD = "YOUR_WIFI_PASSWORD"; // CHANGE TO YOUR WIFI PASSWORD
const char* TCP_SERVER_ADDR = "192.168.0.26"; // CHANGE TO TCP SERVER'S IP ADDRESS
const int TCP_SERVER_PORT = 1470;
WiFiClient TCP_client;
void setup() {
Serial.begin(9600);
rs422.begin(9600);
Serial.println("Arduino: TCP CLIENT");
// check for the WiFi module:
if (WiFi.status() == WL_NO_MODULE) {
Serial.println("Communication with WiFi module failed!");
// don't continue
while (true)
;
}
String fv = WiFi.firmwareVersion();
if (fv < WIFI_FIRMWARE_LATEST_VERSION) {
Serial.println("Please upgrade the firmware");
}
Serial.print("Attempting to connect to SSID: ");
Serial.println(WIFI_SSID);
// attempt to connect to WiFi network:
while (WiFi.begin(WIFI_SSID, WIFI_PASSWORD) != WL_CONNECTED) {
delay(10000); // wait 10 seconds for connection:
}
Serial.print("Connected to WiFi ");
Serial.println(WIFI_SSID);
// connect to TCP server
if (TCP_client.connect(TCP_SERVER_ADDR, TCP_SERVER_PORT))
Serial.println("Connected to TCP server");
else
Serial.println("Failed to connect to TCP server");
}
void loop() {
if (TCP_client.connected()) {
// read data from TCP and send them to RS422 interface
if (TCP_client.available()) {
char c = TCP_client.read();
rs422.write(c);
}
// read data from RS422 interface and send them to TCP
if (rs422.available()) {
char c = rs422.read();
TCP_client.write(c);
}
} else {
Serial.println("Connection is disconnected");
TCP_client.stop();
// reconnect to TCP server
if (TCP_client.connect(TCP_SERVER_ADDR, TCP_SERVER_PORT)) {
Serial.println("Reconnected to TCP server");
} else {
Serial.println("Failed to reconnect to TCP server");
delay(1000);
}
}
}
Test
Vous pouvez effectuer un test en envoyant des données dans les flux suivants :
- Logiciel série (sur votre PC) → RS-422 → Arduino → WiFi → Logiciel serveur TCP (sur votre PC).
- Logiciel serveur TCP (sur votre PC) → WiFi → Arduino → RS-422 → Logiciel série (sur votre PC).
Pour ce faire, suivez les étapes ci-dessous :
- Si c'est la première fois que vous utilisez l'Arduino Uno R4, consultez comment configurer l'environnement pour Arduino Uno R4 sur Arduino IDE.
- Connectez l'Arduino Uno R4 WiFi à votre PC en utilisant un module TTL-vers-RS422 et un câble RS422-vers-USB comme le montre le schéma de câblage ci-dessus.
- Installez un programme de serveur TCP comme ezTerm
- Ouvrez le programme série et configurez les paramètres série (port COM, baurate...)
- Ouvrez le programme serveur TCP et configurez-le comme serveur TCP, puis cliquez sur le bouton Écouter.
- Ouvrez l'invite de commande sur votre PC.
- Trouvez l'adresse IP de votre PC en exécutant la commande ci-dessous :
ipconfig
- La sortie ressemble à ce qui suit :
Command Prompt
C:\WINDOWS\system32>ipconfig
Windows IP Configuration
Ethernet adapter:
Subnet Mask . . . . . . . . . . . : 255.0.0.0
IPv4 Address. . . . . . . . . . . : 192.168.0.26
Subnet Mask . . . . . . . . . . . : 255.255.255.0
Default Gateway . . . . . . . . . :
- Mettez à jour l'adresse IP du serveur TCP (Votre PC) dans le code Arduino. Dans l'exemple ci-dessus : 192.168.0.26
- Compilez et téléchargez le code sur la carte Arduino en cliquant sur le bouton Upload dans l'IDE Arduino
- Tapez des données depuis le programme Série pour les envoyer à Arduino via Série.
- Si cela réussit, vous verrez les données écho sur le logiciel serveur TCP.
- Tapez des données depuis le programme serveur TCP pour les envoyer à Arduino via TCP.
- Si cela réussit, vous verrez les données écho sur le programme Série.
Si vous souhaitez utiliser un convertisseur commercial RS422 vers Ethernet, vous pouvez acheter le Convertisseur série vers Ethernet CSE-H55N2