Arduino - Moteur pas à pas et interrupteur de fin de course
Dans ce tutoriel Arduino, nous allons apprendre à utiliser un Arduino, un interrupteur de fin de course, un pilote L298N et un moteur pas à pas. En détail, nous allons apprendre :
- Comment arrêter le moteur pas à pas lorsqu'un interrupteur de fin de course est touché
- Comment changer la direction du moteur pas à pas lorsque un interrupteur de fin de course est touché
- Comment changer la direction du moteur pas à pas lorsque deux interrupteurs de fin de course sont touchés
Préparation du matériel
Or you can buy the following sensor kits:
| 1 | × | DIYables Sensor Kit (30 sensors/displays) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgation : Certains des liens fournis dans cette section sont des liens affiliés Amazon. Nous pouvons recevoir une commission pour tout achat effectué via ces liens, sans coût supplémentaire pour vous. Nous vous remercions de votre soutien.
À propos du moteur pas à pas et de l'interrupteur de fin de course
Si vous ne connaissez pas le moteur pas à pas et l'interrupteur de fin de course (brochage, fonctionnement, programmation...), renseignez-vous à leur sujet dans les tutoriels suivants :
- Arduino - Limit Switch tutorial
- Arduino - Controls Stepper Motor tutorial
Diagramme de câblage
Ce tutoriel fournit les codes Arduino pour deux cas : un moteur pas à pas + un interrupteur de fin de course, un moteur pas à pas + deux interrupteurs de fin de course.
- Schéma de câblage entre le moteur pas à pas et un interrupteur de fin de course
This image is created using Fritzing. Click to enlarge image
- Schéma de câblage entre le moteur pas à pas et deux interrupteurs de fin de course
This image is created using Fritzing. Click to enlarge image
※ NOTE THAT:
Selon le moteur pas à pas, la connexion des câbles entre le moteur pas à pas et le L298N peut être différente. Veuillez examiner attentivement ce tutoriel Arduino - Moteur Pas à Pas pour voir comment connecter le moteur pas à pas au pilote de moteur L298N.
Code Arduino - Arrêter un moteur pas à pas avec un interrupteur de fin de course
Il existe plusieurs façons de faire arrêter un moteur pas à pas :
- Appelez la fonction stepper.stop() : Cette méthode ne permet PAS d'arrêter immédiatement le moteur pas à pas, mais progressivement.
- Ne PAS appeler la fonction stepper.run() : Cette méthode arrête immédiatement le moteur pas à pas.
Le code ci-dessous fait tourner un moteur pas à pas indéfiniment et s'arrête immédiatement lorsqu'un interrupteur de fin de course est touché.
/*
* Ce code Arduino a été développé par newbiely.fr
* Ce code Arduino est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino/arduino-stepper-motor-and-limit-switch
*/
#include <ezButton.h>
#include <AccelStepper.h>
#define MAX_POSITION 0x7FFFFFFF // maximum of position we can set (long type)
ezButton limitSwitch(A0); // create ezButton object that attach to pin A0;
AccelStepper stepper(AccelStepper::FULL4WIRE, 7, 6, 5, 4);
bool isStopped = false;
void setup() {
Serial.begin(9600);
limitSwitch.setDebounceTime(50); // set debounce time to 50 milliseconds
stepper.setMaxSpeed(500.0); // set the maximum speed
stepper.setAcceleration(50.0); // set acceleration
stepper.setSpeed(100); // set initial speed
stepper.setCurrentPosition(0); // set position
stepper.moveTo(MAX_POSITION);
}
void loop() {
limitSwitch.loop(); // MUST call the loop() function first
if (limitSwitch.isPressed()) {
Serial.println(F("The limit switch: TOUCHED"));
isStopped = true;
}
if (isStopped == false) {
// without this part, the move will stop after reaching maximum position
if (stepper.distanceToGo() == 0) { // if motor moved to the maximum position
stepper.setCurrentPosition(0); // reset position to 0
stepper.moveTo(MAX_POSITION); // move the motor to maximum position again
}
stepper.run(); // MUST be called in loop() function
} else {
// without calling stepper.run() function, motor stops immediately
// NOTE: stepper.stop() function does NOT stops motor immediately
Serial.println(F("The stepper motor is STOPPED"));
}
}
Étapes rapides
- Connectez l'Arduino au PC via un câble USB
- Ouvrez l'IDE Arduino, sélectionnez la bonne carte et le bon port
- Naviguez jusqu'à l'icône Libraries sur la barre gauche de l'IDE Arduino.
- Recherchez "ezButton", puis trouvez la bibliothèque de boutons par ArduinoGetStarted.com
- Cliquez sur le bouton Install pour installer la bibliothèque ezButton.
- Recherchez "AccelStepper", puis trouvez la bibliothèque AccelStepper de Mike McCauley
- Cliquez sur le bouton Install pour installer la bibliothèque AccelStepper.
- Copiez le code ci-dessus et ouvrez-le avec Arduino IDE
- Cliquez sur le bouton Upload sur Arduino IDE pour téléverser le code vers Arduino
- Si le câblage est correct, vous verrez le moteur tourner dans le sens horaire.
- Touchez l'interrupteur de fin de course
- Vous verrez que le moteur s'arrête immédiatement
- Le résultat sur le moniteur série apparaît comme ci-dessous
COM6
The limit switch: TOUCHED
The stepper motor is STOPPED
The stepper motor is STOPPED
The stepper motor is STOPPED
The stepper motor is STOPPED
Autoscroll
Clear output
9600 baud
Newline
Explication du code
Vous pouvez trouver l'explication dans la ligne de commentaires du code Arduino ci-dessus.
Code Arduino - Changer le sens du moteur pas à pas à l'aide d'un interrupteur de fin de course
Le code ci-dessous permet de faire tourner un moteur pas à pas indéfiniment et de changer sa direction lorsqu'un interrupteur de fin de course est touché.
/*
* Ce code Arduino a été développé par newbiely.fr
* Ce code Arduino est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino/arduino-stepper-motor-and-limit-switch
*/
#include <ezButton.h>
#include <AccelStepper.h>
#define DIRECTION_CCW -1
#define DIRECTION_CW 1
#define MAX_POSITION 0x7FFFFFFF // maximum of position we can set (long type)
ezButton limitSwitch(A0); // create ezButton object that attach to pin A0;
AccelStepper stepper(AccelStepper::FULL4WIRE, 7, 6, 5, 4);
int direction = DIRECTION_CW;
long targetPos = 0;
void setup() {
Serial.begin(9600);
limitSwitch.setDebounceTime(50); // set debounce time to 50 milliseconds
stepper.setMaxSpeed(500.0); // set the maximum speed
stepper.setAcceleration(50.0); // set acceleration
stepper.setSpeed(100); // set initial speed
stepper.setCurrentPosition(0); // set position
targetPos = direction * MAX_POSITION;
stepper.moveTo(targetPos);
}
void loop() {
limitSwitch.loop(); // MUST call the loop() function first
if (limitSwitch.isPressed()) {
Serial.println(F("The limit switch: TOUCHED"));
direction *= -1; // change direction
Serial.print(F("The direction -> "));
if (direction == DIRECTION_CW)
Serial.println(F("CLOCKWISE"));
else
Serial.println(F("ANTI-CLOCKWISE"));
targetPos = direction * MAX_POSITION;
stepper.setCurrentPosition(0); // set position
stepper.moveTo(targetPos);
}
// without this part, the move will stop after reaching maximum position
if (stepper.distanceToGo() == 0) { // if motor moved to the maximum position
stepper.setCurrentPosition(0); // reset position to 0
stepper.moveTo(targetPos); // move the motor to maximum position again
}
stepper.run(); // MUST be called in loop() function
}
Étapes rapides
- Copiez le code ci-dessus et ouvrez-le avec Arduino IDE
- Cliquez sur le bouton Upload de l'Arduino IDE pour charger le code sur l'Arduino
- Si le câblage est correct, vous verrez le moteur tourner dans le sens des aiguilles d'une montre.
- Touchez l'interrupteur de fin de course
- Vous verrez que la direction du moteur pas à pas est changée en sens antihoraire
- Touchez de nouveau l'interrupteur de fin de course
- Vous verrez que la direction du moteur pas à pas est changée en sens horaire
- Le résultat sur le moniteur série apparaît comme ci-dessous
COM6
The limit switch: TOUCHED
The direction -> ANTI-CLOCKWISE
The limit switch: TOUCHED
The direction -> CLOCKWISE
Autoscroll
Clear output
9600 baud
Newline
Code Arduino - Changer la direction d'un moteur pas à pas avec deux interrupteurs de fin de course
Le code ci-dessous permet de faire tourner un moteur pas à pas indéfiniment et de changer sa direction lorsqu'un des deux interrupteurs de fin de course est actionné.
/*
* Ce code Arduino a été développé par newbiely.fr
* Ce code Arduino est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino/arduino-stepper-motor-and-limit-switch
*/
#include <ezButton.h>
#include <AccelStepper.h>
#define DIRECTION_CCW -1
#define DIRECTION_CW 1
#define STATE_CHANGE_DIR 1
#define STATE_MOVE 2
#define STATE_MOVING 3
#define MAX_POSITION 0x7FFFFFFF // maximum of position we can set (long type)
ezButton limitSwitch_1(A0); // create ezButton object that attach to pin A0;
ezButton limitSwitch_2(A1); // create ezButton object that attach to pin A1;
AccelStepper stepper(AccelStepper::FULL4WIRE, 7, 6, 5, 4);
int stepperState = STATE_MOVE;
int direction = DIRECTION_CW;
long targetPos = 0;
void setup() {
Serial.begin(9600);
limitSwitch_1.setDebounceTime(50); // set debounce time to 50 milliseconds
limitSwitch_2.setDebounceTime(50); // set debounce time to 50 milliseconds
stepper.setMaxSpeed(500.0); // set the maximum speed
stepper.setAcceleration(50.0); // set acceleration
stepper.setSpeed(100); // set initial speed
stepper.setCurrentPosition(0); // set position
}
void loop() {
limitSwitch_1.loop(); // MUST call the loop() function first
limitSwitch_2.loop(); // MUST call the loop() function first
if (limitSwitch_1.isPressed()) {
stepperState = STATE_CHANGE_DIR;
Serial.println(F("The limit switch 1: TOUCHED"));
}
if (limitSwitch_2.isPressed()) {
stepperState = STATE_CHANGE_DIR;
Serial.println(F("The limit switch 2: TOUCHED"));
}
switch (stepperState) {
case STATE_CHANGE_DIR:
direction *= -1; // change direction
Serial.print(F("The direction -> "));
if (direction == DIRECTION_CW)
Serial.println(F("CLOCKWISE"));
else
Serial.println(F("ANTI-CLOCKWISE"));
stepperState = STATE_MOVE; // after changing direction, go to the next state to move the motor
break;
case STATE_MOVE:
targetPos = direction * MAX_POSITION;
stepper.setCurrentPosition(0); // set position
stepper.moveTo(targetPos);
stepperState = STATE_MOVING; // after moving, go to the next state to keep the motor moving infinity
break;
case STATE_MOVING: // without this state, the move will stop after reaching maximum position
if (stepper.distanceToGo() == 0) { // if motor moved to the maximum position
stepper.setCurrentPosition(0); // reset position to 0
stepper.moveTo(targetPos); // move the motor to maximum position again
}
break;
}
stepper.run(); // MUST be called in loop() function
}
Étapes rapides
- Copiez le code ci-dessus et ouvrez-le avec l'IDE Arduino
- Cliquez sur le bouton Upload sur l'IDE Arduino pour téléverser le code sur Arduino
- Si le câblage est correct, vous verrez le moteur tourner dans le sens horaire.
- Touchez l'interrupteur de limite 1
- Vous verrez que la direction du moteur pas à pas est changée en sens antihoraire
- Touchez l'interrupteur de limite 2
- Vous verrez que la direction du moteur pas à pas est changée en sens horaire
- Le résultat sur le moniteur série apparaît comme ci-dessous
COM6
The limit switch 1: TOUCHED
The direction -> ANTI-CLOCKWISE
The limit switch 2: TOUCHED
The direction -> CLOCKWISE
Autoscroll
Clear output
9600 baud
Newline