Arduino - LCD 20x4
Dans ce tutoriel Arduino LCD 20x4 I2C, nous allons apprendre à connecter un écran LCD 20x4 (affichage à cristaux liquides) à une carte Arduino via l'interface I2C.
Préparation du matériel
Ou vous pouvez acheter les kits suivants:
| 1 | × | Kit de Démarrage DIYables STEM V3 (Arduino inclus) | |
| 1 | × | Kit de Capteurs DIYables (18 capteurs/écrans) |
Divulgation : Certains des liens fournis dans cette section sont des liens affiliés Amazon. Nous pouvons recevoir une commission pour tout achat effectué via ces liens, sans coût supplémentaire pour vous. Nous vous remercions de votre soutien.
Note d'achat: Une autre option consiste à créer l'écran LCD I2C en associant LCD 2004 Display et PCF8574 I2C Adapter Module.
À propos de LCD I2C 20x4
Brochage
L'écran LCD 20x4 I2C utilise une interface I2C, donc il possède 4 broches :
- Broche GND : doit être connectée à GND (0V).
- Broche VCC : l'alimentation pour l'afficheur LCD, doit être connectée à VCC (5V).
- Broche SDA : signal de données I2C
- Broche SCL : signal d'horloge I2C
Coordonnée LCD
L'écran LCD I2C 20x4 comprend 20 colonnes et 4 rangées. Les colonnes et les rangées sont indexées à partir de 0.
Diagramme de câblage
Cette image a été créée avec Fritzing. Cliquez pour agrandir l'image.
| LCD I2C | Arduino Uno, Nano | Arduino Mega |
|---|---|---|
| Vin | 5V | 5V |
| GND | GND | GND |
| SDA | A4 | 20 |
| SCL | A5 | 21 |
Comment programmer pour un LCD I2C
Grâce à la bibliothèque DIYables_LCD_I2C, utiliser un LCD est un jeu d'enfant.
- Inclure la bibliothèque :
#include <DIYables_LCD_I2C.h> // Bibliothèque pour LCD
- Déclarez un objet DIYables_LCD_I2C avec l’adresse I2C, le nombre de colonnes, le nombre de lignes :
DIYables_LCD_I2C lcd(0x27, 20, 4); // Adresse I2C 0x27, 20 colonnes et 4 rangées
- Initialisez l'écran LCD.
lcd.init(); //initialiser l'afficheur LCD
lcd.backlight(); //allumer le rétroéclairage
- Déplacez le curseur à la position souhaitée (indice_colonne, indice_ligne)
lcd.setCursor(column_index, row_index);
- Imprimez un message sur l'écran LCD.
lcd.print("Hello World!");
※ Note:
L'adresse I2C de l'écran LCD peut varier selon les fabricants. Dans le code, nous avons utilisé 0x27 qui est spécifié par le fabricant DIYables.
Code Arduino
/*
* Ce code Arduino a été développé par newbiely.fr
* Ce code Arduino est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino/arduino-lcd-20x4
*/
#include <DIYables_LCD_I2C.h>
DIYables_LCD_I2C lcd(0x27, 20, 4); // Adresse I2C 0x27, 20 colonnes et 4 lignes
void setup() {
lcd.init(); // initialiser le lcd
lcd.backlight();
lcd.setCursor(0, 0); // déplacer le curseur à la première ligne
lcd.print("LCD 20x4"); // afficher le message à la première ligne
lcd.setCursor(0, 1); // déplacer le curseur à la deuxième ligne
lcd.print("I2C Address: 0x27"); // afficher le message à la deuxième ligne
lcd.setCursor(0, 2); // déplacer le curseur à la troisième ligne
lcd.print("DIYables"); // afficher le message à la troisième ligne
lcd.setCursor(0, 3); // déplacer le curseur à la quatrième ligne
lcd.print("www.diyables.io"); // afficher le message à la quatrième ligne
}
void loop() {
}
Étapes rapides
- Naviguez vers l'icône Libraries dans la barre latérale gauche de l'IDE Arduino.
- Recherchez "DIYables LCD I2C", puis trouvez la bibliothèque DIYables_LCD_I2C de DIYables.
- Cliquez sur le bouton Install pour installer la bibliothèque DIYables_LCD_I2C.
- Copiez le code ci-dessus et ouvrez-le avec l'IDE Arduino
- Cliquez sur le bouton Upload de l'IDE Arduino pour téléverser le code vers l'Arduino
- Voir le résultat sur l'écran LCD
- Essayez de modifier le texte et la position.
Vidéo
La démo vidéo ci-dessous utilise le code ci-dessous. Notez que la vidéo montre l'Arduino Uno R4, mais cela fonctionne de manière identique pour l'Arduino Uno R3 :
/*
* Ce code Arduino a été développé par newbiely.fr
* Ce code Arduino est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino/arduino-lcd-20x4
*/
#include <Wire.h>
#include <DIYables_LCD_I2C.h>
#include <SPI.h>
#include <MFRC522.h>
#include <Servo.h>
// ================= LCD =================
DIYables_LCD_I2C lcd(0x27, 20, 4);
// ================= RFID =================
#define SS_PIN 10
#define RST_PIN 9
MFRC522 rfid(SS_PIN, RST_PIN);
// ================= SERVO =================
Servo doorServo;
#define SERVO_PIN 6
// ================= BUZZER =================
#define BUZZER 8
// ================= ADMIN UID =================
byte adminUID[4] = {0x3C, 0x7F, 0xB3, 0x02};
// ================= STATE =================
enum State { IDLE, SCANNING, GRANTED, DENIED, LOCKED };
State systemState = IDLE;
int failCount = 0;
unsigned long stateTime = 0;
unsigned long lockTime = 0;
// ================= SOUND =================
void beepOK() {
for (int i = 0; i < 2; i++) {
digitalWrite(BUZZER,HIGH);
delay(100);
digitalWrite(BUZZER,LOW);
delay(50);
}
}
void beepFail() {
for (int i = 0; i < 3; i++) {
digitalWrite(BUZZER,HIGH);
delay(150);
digitalWrite(BUZZER,LOW);
delay(80);
}
}
void beepLock() {
digitalWrite(BUZZER,HIGH);
delay(300);
digitalWrite(BUZZER,LOW);
}
// ================= DISPLAY IDLE =================
void showIdle() {
lcd.clear();
lcd.setCursor(0,0); lcd.print("SYSTEM READY");
lcd.setCursor(0,1); lcd.print("PLEASE SCAN CARD");
lcd.setCursor(0,2); lcd.print("DOOR: LOCKED");
lcd.setCursor(0,3); lcd.print("SECURITY: ACTIVE");
Serial.println("[STATE] IDLE");
systemState = IDLE;
}
// ================= DISPLAY SCANNING =================
void showScanning() {
lcd.clear();
lcd.setCursor(0,1);
lcd.print("SCANNING CARD...");
Serial.println("[STATE] SCANNING");
systemState = SCANNING;
}
// ================= GRANTED =================
void showGranted() {
lcd.clear();
lcd.setCursor(0,0); lcd.print("SYSTEM: GRANTED");
lcd.setCursor(0,1); lcd.print("USER: ADMIN");
lcd.setCursor(0,2); lcd.print("OPENING DOOR...");
lcd.setCursor(0,3); lcd.print("AUTO LOCK 3s");
doorServo.write(90);
beepOK();
stateTime = millis();
systemState = GRANTED;
Serial.println("[STATE] GRANTED");
}
// ================= DENIED =================
void showDenied(byte *uid) {
lcd.clear();
lcd.setCursor(0,0); lcd.print("SYSTEM: DENIED");
lcd.setCursor(0,1); lcd.print("UID: ");
for (byte i=0;i<4;i++) {
lcd.print(uid[i], HEX);
lcd.print(" ");
}
lcd.setCursor(0,2); lcd.print("ACCESS BLOCKED");
failCount++;
lcd.setCursor(0,3);
lcd.print("FAIL: ");
lcd.print(failCount);
lcd.print("/3");
beepFail();
stateTime = millis();
systemState = DENIED;
Serial.println("[STATE] DENIED");
}
// ================= CHECK UID =================
bool isAdmin(byte *uid) {
for (byte i=0;i<4;i++) {
if (uid[i] != adminUID[i]) return false;
}
return true;
}
// ================= LOCK SYSTEM =================
void lockSystem() {
systemState = LOCKED;
lcd.clear();
lcd.setCursor(0,1);
lcd.print("SYSTEM LOCKED!");
lcd.setCursor(0,2);
lcd.print("TOO MANY FAILS");
doorServo.write(0);
beepLock();
Serial.println("[STATE] LOCKED");
delay(3000);
failCount = 0;
showIdle();
}
// ================= SETUP =================
void setup() {
Serial.begin(9600);
lcd.init();
lcd.backlight();
SPI.begin();
rfid.PCD_Init();
doorServo.attach(SERVO_PIN);
doorServo.write(0);
pinMode(BUZZER, OUTPUT);
showIdle();
}
// ================= LOOP =================
void loop() {
// LOCK CONDITION
if (failCount >= 3 && systemState != LOCKED) {
lockSystem();
return;
}
// AUTO BACK TO IDLE FROM DENIED
if (systemState == DENIED && millis() - stateTime > 2000) {
showIdle();
}
// AUTO CLOSE DOOR
if (systemState == GRANTED && millis() - stateTime > 3000) {
doorServo.write(0);
beepLock();
showIdle();
}
// RFID READ
if (!rfid.PICC_IsNewCardPresent()) return;
if (!rfid.PICC_ReadCardSerial()) return;
showScanning();
byte *uid = rfid.uid.uidByte;
Serial.print("UID: ");
for (byte i=0;i<rfid.uid.size;i++) {
Serial.print(uid[i], HEX);
Serial.print(" ");
}
Serial.println();
delay(300);
if (isAdmin(uid)) {
showGranted();
} else {
showDenied(uid);
}
rfid.PICC_HaltA();
}