Arduino Uno R4 WiFi contrôle le relais via le Web
Dans ce tutoriel, nous apprendrons à contrôler un relais via une interface web accessible depuis un navigateur sur un PC ou un smartphone. Nous utiliserons la carte Arduino Uno R4 WiFi, qui sera programmée pour fonctionner comme un serveur web. Supposons que l'adresse IP de l'Arduino Uno R4 WiFi soit 192.168.0.2. Voici comment cela fonctionne :
- Pour accéder à l'interface web, entrez simplement 192.168.0.2 dans la barre d'adresse de votre navigateur web. Cela enverra une requête à l'Arduino, et en réponse, l'Arduino fournira une page web contenant un bouton marche/arrêt pour contrôler le relais.
- De même, si vous cliquez sur le bouton RELAY ON sur la page web ou entrez 192.168.0.2/relay1/on dans le navigateur web, l'Arduino activera le relais et répondra avec la page web mise à jour.
- De la même façon, si vous cliquez sur le bouton RELAY OFF sur la page web ou entrez 192.168.0.2/relay1/off dans le navigateur web, l'Arduino désactivera le relais et répondra avec la page web mise à jour.
En connectant un relais à des appareils tels qu'un verrou à solénoïde, une ampoule, une bande LED, un moteur ou un actionneur, nous pouvons les contrôler via une interface web.
Le tutoriel fournit une base que vous pouvez facilement et créativement personnaliser pour réaliser ce qui suit :
- Contrôlez plusieurs relais via une interface web.
- Redessinez l'interface utilisateur web (UI) selon vos préférences.
Préparation du matériel
Or you can buy the following sensor kits:
| 1 | × | DIYables Sensor Kit (30 sensors/displays) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgation : Certains des liens fournis dans cette section sont des liens affiliés Amazon. Nous pouvons recevoir une commission pour tout achat effectué via ces liens, sans coût supplémentaire pour vous. Nous vous remercions de votre soutien.
À propos du relais et de l'Arduino Uno R4
Si vous ne connaissez pas l'Arduino Uno R4 et le relais (brochage, fonctionnement, programmation...), renseignez-vous à leur sujet dans les tutoriels suivants :
Diagramme de câblage
This image is created using Fritzing. Click to enlarge image
Code Arduino
/*
* Ce code Arduino a été développé par newbiely.fr
* Ce code Arduino est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino/arduino-uno-r4-wifi-controls-relay-via-web
*/
#include <WiFiS3.h>
#define RELAY_PIN 7 // Arduino pin connected to relay's pin
const char ssid[] = "YOUR_WIFI"; // change your network SSID (name)
const char pass[] = "YOUR_WIFI_PASSWORD"; // change your network password (use for WPA, or use as key for WEP)
int status = WL_IDLE_STATUS;
WiFiServer server(80);
void setup() {
//Initialize serial and wait for port to open:
Serial.begin(9600);
pinMode(RELAY_PIN, OUTPUT); // set arduino pin to output mode
String fv = WiFi.firmwareVersion();
if (fv < WIFI_FIRMWARE_LATEST_VERSION) {
Serial.println("Please upgrade the firmware");
}
// attempt to connect to WiFi network:
while (status != WL_CONNECTED) {
Serial.print("Attempting to connect to SSID: ");
Serial.println(ssid);
// Connect to WPA/WPA2 network. Change this line if using open or WEP network:
status = WiFi.begin(ssid, pass);
// wait 10 seconds for connection:
delay(10000);
}
server.begin();
// you're connected now, so print out the status:
printWifiStatus();
}
void loop() {
// listen for incoming clients
WiFiClient client = server.available();
if (client) {
// read the first line of HTTP request header
String HTTP_req = "";
while (client.connected()) {
if (client.available()) {
Serial.println("New HTTP Request");
HTTP_req = client.readStringUntil('\n'); // read the first line of HTTP request
Serial.print("<< ");
Serial.println(HTTP_req); // print HTTP request to Serial Monitor
break;
}
}
// read the remaining lines of HTTP request header
while (client.connected()) {
if (client.available()) {
String HTTP_header = client.readStringUntil('\n'); // read the header line of HTTP request
if (HTTP_header.equals("\r")) // the end of HTTP request
break;
Serial.print("<< ");
Serial.println(HTTP_header); // print HTTP request to Serial Monitor
}
}
if (HTTP_req.indexOf("GET") == 0) { // check if request method is GET
// expected header is one of the following:
// - GET relay1/on
// - GET relay1/off
if (HTTP_req.indexOf("relay1/on") > -1) { // check the path
digitalWrite(RELAY_PIN, HIGH); // turn on relay
Serial.println("Turned relay on");
} else if (HTTP_req.indexOf("relay1/off") > -1) { // check the path
digitalWrite(RELAY_PIN, LOW); // turn off relay
Serial.println("Turned relay off");
} else {
Serial.println("No command");
}
}
// send the HTTP response
// send the HTTP response header
client.println("HTTP/1.1 200 OK");
client.println("Content-Type: text/html");
client.println("Connection: close"); // the connection will be closed after completion of the response
client.println(); // the separator between HTTP header and body
// send the HTTP response body
client.println("<!DOCTYPE HTML>");
client.println("<html>");
client.println("<head>");
client.println("<link rel=\"icon\" href=\"data:,\">");
client.println("</head>");
client.println("<a href=\"/relay1/on\">RELAY ON</a>");
client.println("<br><br>");
client.println("<a href=\"/relay1/off\">RELAY OFF</a>");
client.println("</html>");
client.flush();
// give the web browser time to receive the data
delay(10);
// close the connection:
client.stop();
}
}
void printWifiStatus() {
// print your board's IP address:
Serial.print("IP Address: ");
Serial.println(WiFi.localIP());
// print the received signal strength:
Serial.print("signal strength (RSSI):");
Serial.print(WiFi.RSSI());
Serial.println(" dBm");
}
Étapes rapides
- Si c'est la première fois que vous utilisez un Arduino Uno R4, consultez comment configurer l'environnement pour Arduino Uno R4 sur Arduino IDE.
- Copiez le code ci-dessus et ouvrez-le avec l'Arduino IDE
- Modifiez les informations wifi (SSID et mot de passe) dans le code pour les vôtres
- Cliquez sur le bouton Upload dans l'Arduino IDE pour charger le code sur Arduino
- Ouvrez le moniteur série
- Consultez le résultat sur le moniteur série.
COM6
Attempting to connect to SSID: YOUR_WIFI
IP Address: 192.168.0.2
signal strength (RSSI):-39 dBm
Autoscroll
Clear output
9600 baud
Newline
- Vous verrez une adresse IP, par exemple : 192.168.0.2. C'est l'adresse IP du serveur Web Arduino.
- Ouvrez un navigateur web et entrez l'un des trois formats ci-dessous dans la barre d'adresse :
192.168.0.2
192.168.0.2/relay1/on
192.168.0.2/relay1/off
- Veuillez noter que l'adresse IP peut être différente. Assurez-vous de vérifier la valeur actuelle sur le moniteur série.
- De plus, vous observerez la sortie suivante sur le moniteur série.
COM6
Attempting to connect to SSID: YOUR_WIFI
IP Address: 192.168.0.2
signal strength (RSSI):-41 dBm
New HTTP Request
<< GET /relay1/on HTTP/1.1
<< Host: 192.168.0.2
<< Connection: keep-alive
<< Cache-Control: max-age=0
<< Upgrade-Insecure-Requests: 1
<< User-Agent: Mozilla/5.0 (Windows NT 10.0; Win64; x64)
<< Accept: text/html,application/xhtml+xml,application/xml
<< Accept-Encoding: gzip, deflate
<< Accept-Language: en-US,en;q=0.9
Turned relay on
Autoscroll
Clear output
9600 baud
Newline
- Vérifiez l'état du relais
- Vous verrez la page web de la carte Arduino dans le navigateur web comme ci-dessous :
Désormais, vous avez la capacité de contrôler l'état marche/arrêt du relais via l'interface web. Vous pouvez également personnaliser facilement et de manière créative le code pour réaliser ce qui suit :
- Contrôlez plusieurs relais via une interface web.
- Redessinez l'interface utilisateur (UI) web selon vos préférences.
Si vous souhaitez améliorer l'apparence de la page Web avec une interface graphique utilisateur (UI) impressionnante, vous pouvez consulter le tutoriel Arduino - Serveur Web pour inspiration et orientation.