Arduino - LED - Clignotement sans délai
Imaginons qu'Arduino doive effectuer deux tâches : faire clignoter une LED et vérifier l'état d'un bouton, qui peut être pressé à tout moment. Si nous utilisons la fonction delay() (décrite dans un tutoriel précédent), Arduino pourrait manquer certains des événements de pression. En d'autres termes, Arduino ne peut pas accomplir pleinement la deuxième tâche.
Dans ce tutoriel, nous apprendrons comment Arduino fait clignoter une LED et vérifie l'état du bouton sans manquer aucun événement de pression.
Nous examinerons trois exemples ci-dessous et comparerons les différences entre eux.
- Arduino fait clignoter la LED en utilisant la fonction delay().
- Arduino fait clignoter la LED en utilisant la fonction millis().
- Arduino fait clignoter la LED en utilisant la bibliothèque ezLED.
※ NOTE THAT:
- Cette méthode ne sert pas uniquement à faire clignoter une LED et à vérifier l'état d'un bouton. En général, cette méthode permet à Arduino d'effectuer plusieurs tâches en même temps sans qu'elles se bloquent mutuellement.
- Ce tutoriel fournit des connaissances approfondies qui vous aideront à comprendre le principe de fonctionnement. Pour simplifier, vous pouvez utiliser la bibliothèque Arduino - LED.
Préparation du matériel
Or you can buy the following sensor kits:
| 1 | × | DIYables Sensor Kit (30 sensors/displays) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgation : Certains des liens fournis dans cette section sont des liens affiliés Amazon. Nous pouvons recevoir une commission pour tout achat effectué via ces liens, sans coût supplémentaire pour vous. Nous vous remercions de votre soutien.
À propos des LED et des boutons.
Si vous ne connaissez pas les LED et les boutons (brochage, fonctionnement, programmation...), renseignez-vous sur ces éléments dans les tutoriels suivants :
Diagramme de câblage
This image is created using Fritzing. Click to enlarge image
Code Arduino - Avec Délai
/*
* Ce code Arduino a été développé par newbiely.fr
* Ce code Arduino est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino/arduino-led-blink-without-delay
*/
// constants won't change:
const int LED_PIN = 3; // the number of the LED pin
const int BUTTON_PIN = 7; // the number of the button pin
const long BLINK_INTERVAL = 1000; // interval at which to blink LED (milliseconds)
// Variables will change:
int ledState = LOW; // ledState used to set the LED
int previousButtonState = LOW; // will store last time button was updated
void setup() {
Serial.begin(9600);
// set the digital pin as output:
pinMode(LED_PIN, OUTPUT);
// set the digital pin as an input:
pinMode(BUTTON_PIN, INPUT);
}
void loop() {
// if the LED is off turn it on and vice-versa:
ledState = (ledState == LOW) ? HIGH : LOW;
// set the LED with the ledState of the variable:
digitalWrite(LED_PIN, ledState);
delay(BLINK_INTERVAL); // If button is pressed during this time, Arduino CANNOT detect
int currentButtonState = digitalRead(BUTTON_PIN);
if(currentButtonState != previousButtonState) {
// print out the state of the button:
Serial.println(currentButtonState);
// save the last state of button
previousButtonState = currentButtonState;
}
// DO OTHER WORKS HERE
}
Étapes rapides
- Connectez Arduino au PC via le câble USB
- Ouvrez l'IDE Arduino, sélectionnez la bonne carte et le bon port
- Copiez le code ci-dessus et ouvrez-le avec l'IDE Arduino
- Cliquez sur le bouton Upload de l'IDE Arduino pour téléverser le code sur Arduino
- Ouvrir le moniteur série
- Appuyez sur le bouton 4 fois
- Observer la LED : La LED bascule entre ON/OFF périodiquement toutes les secondes
- Voir la sortie dans le moniteur série
COM6
1
0
Autoscroll
Clear output
9600 baud
Newline
- Sur le moniteur série, certains temps de pression ont été manqués. Cela est dû au fait que, pendant le temps de délai, l'Arduino NE PEUT RIEN faire. Par conséquent, il est incapable de détecter l'événement de pression.
Code Arduino - Sans Délai
/*
* Ce code Arduino a été développé par newbiely.fr
* Ce code Arduino est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino/arduino-led-blink-without-delay
*/
// constants won't change:
const int LED_PIN = 3; // the number of the LED pin
const int BUTTON_PIN = 7; // the number of the button pin
const long BLINK_INTERVAL = 1000; // interval at which to blink LED (milliseconds)
// Variables will change:
int ledState = LOW; // ledState used to set the LED
int previousButtonState = LOW; // will store last time button was updated
unsigned long previousMillis = 0; // will store last time LED was updated
void setup() {
Serial.begin(9600);
// set the digital pin as output:
pinMode(LED_PIN, OUTPUT);
// set the digital pin as an input:
pinMode(BUTTON_PIN, INPUT);
}
void loop() {
// check to see if it's time to blink the LED; that is, if the difference
// between the current time and last time you blinked the LED is bigger than
// the interval at which you want to blink the LED.
unsigned long currentMillis = millis();
if (currentMillis - previousMillis >= BLINK_INTERVAL) {
// if the LED is off turn it on and vice-versa:
ledState = (ledState == LOW) ? HIGH : LOW;
// set the LED with the ledState of the variable:
digitalWrite(LED_PIN, ledState);
// save the last time you blinked the LED
previousMillis = currentMillis;
}
// check button state's change
int currentButtonState = digitalRead(BUTTON_PIN);
if(currentButtonState != previousButtonState) {
// print out the state of the button:
Serial.println(currentButtonState);
// save the last state of button
previousButtonState = currentButtonState;
}
// DO OTHER WORKS HERE
}
Étapes rapides
- Exécutez le code ci-dessus et appuyez sur le bouton 4 fois
- Observez la LED : La LED bascule périodiquement entre ON/OFF toutes les secondes
- Consultez la sortie dans le moniteur série
COM6
1
0
1
0
1
0
1
0
Autoscroll
Clear output
9600 baud
Newline
- Tous les événements urgents ont été détectés.
Explication du Code
Vous pouvez trouver l'explication dans la ligne des commentaires du code Arduino ci-dessus.
Ajouter plus de tâches
Le code ci-dessous fait clignoter deux LED à des intervalles différents et vérifie l'état du bouton.
/*
* Ce code Arduino a été développé par newbiely.fr
* Ce code Arduino est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino/arduino-led-blink-without-delay
*/
// constants won't change:
const int LED_PIN_1 = 3; // the number of the LED 1 pin
const int LED_PIN_2 = LED_BUILTIN; // the number of the LED 2 pin
const int BUTTON_PIN = 7; // the number of the button pin
const long BLINK_INTERVAL_1 = 1000; // interval at which to blink LED 1 (milliseconds)
const long BLINK_INTERVAL_2 = 500; // interval at which to blink LED 2 (milliseconds)
// Variables will change:
int ledState_1 = LOW; // ledState used to set the LED 1
int ledState_2 = LOW; // ledState used to set the LED 2
int previousButtonState = LOW; // will store last time button was updated
unsigned long previousMillis_1 = 0; // will store last time LED 1 was updated
unsigned long previousMillis_2 = 0; // will store last time LED 2 was updated
void setup() {
Serial.begin(9600);
// set the digital pin as output:
pinMode(LED_PIN_1, OUTPUT);
pinMode(LED_PIN_2, OUTPUT);
// set the digital pin as an input:
pinMode(BUTTON_PIN, INPUT);
}
void loop() {
unsigned long currentMillis = millis();
// check to see if it's time to blink the LED 1
if (currentMillis - previousMillis_1 >= BLINK_INTERVAL_1) {
// if the LED is off turn it on and vice-versa:
ledState_1 = (ledState_1 == LOW) ? HIGH : LOW;
// set the LED with the ledState of the variable:
digitalWrite(LED_PIN_1, ledState_1);
// save the last time you blinked the LED
previousMillis_1 = currentMillis;
}
// check to see if it's time to blink the LED 2
if (currentMillis - previousMillis_2 >= BLINK_INTERVAL_2) {
// if the LED is off turn it on and vice-versa:
ledState_2 = (ledState_2 == LOW) ? HIGH : LOW;
// set the LED with the ledState of the variable:
digitalWrite(LED_PIN_2, ledState_2);
// save the last time you blinked the LED
previousMillis_2 = currentMillis;
}
// check button state's change
int currentButtonState = digitalRead(BUTTON_PIN);
if(currentButtonState != previousButtonState) {
// print out the state of the button:
Serial.println(currentButtonState);
// save the last state of button
previousButtonState = currentButtonState;
}
// DO OTHER WORKS HERE
}
Vidéo
Extensibilité
Cette méthode peut être utilisée pour permettre à Arduino d'effectuer plusieurs tâches simultanément sans se bloquer mutuellement. Par exemple, envoyer une requête sur Internet et attendre la réponse, pendant l'attente de la réponse, faire clignoter des indicateurs LED et vérifier le bouton d'annulation.