Arduino - Lire la configuration depuis une carte SD
Dans ce tutoriel, nous allons apprendre à utiliser le fichier de configuration sur la carte Micro SD. En détail, nous apprendrons :
- Enregistrez un fichier config.txt sur la carte Micro SD. Le fichier contient les paires clé-valeur.
- Lisez la configuration depuis la carte Micro SD et enregistrez-la dans une variable int.
- Lisez la configuration depuis la carte Micro SD et enregistrez-la dans une variable float.
- Lisez la configuration depuis la carte Micro SD et enregistrez-la dans une variable String.
Préparation du matériel
Or you can buy the following sensor kits:
| 1 | × | DIYables Sensor Kit (30 sensors/displays) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgation : Certains des liens fournis dans cette section sont des liens affiliés Amazon. Nous pouvons recevoir une commission pour tout achat effectué via ces liens, sans coût supplémentaire pour vous. Nous vous remercions de votre soutien.
À propos du module de carte Micro SD
Si vous ne connaissez pas le module de carte Micro SD (brochage, fonctionnement, programmation...), renseignez-vous dans le tutoriel Arduino - Carte Micro SD.
Comment ça fonctionne
Les paires clé-valeur sont pré-enregistrées sur la carte Micro SD selon le format suivant :
- Chaque paire clé-valeur est sur une ligne. En d'autres termes, chaque paire clé-valeur est séparée des autres par un caractère de nouvelle ligne.
- La clé et la valeur sont séparées par un caractère =.
Le code Arduino recherchera la clé et trouvera la valeur correspondante, puis enregistrera la valeur dans une variable. Le type de variable peut être int, float ou String.
Diagramme de câblage
This image is created using Fritzing. Click to enlarge image
※ NOTE THAT:
Si vous utilisez un shield Ethernet ou tout autre shield qui possède un support pour carte Micro SD, vous n'avez pas besoin d'utiliser le module de carte Micro SD. Il suffit d'insérer la carte Micro SD dans le support pour carte Micro SD sur le shield.
Comment lire la configuration dans des variables
- Créez le fichier config.txt sur votre PC via Notepad ou Notepad++
- Copiez les paires clé-valeur ci-dessous et collez-les dans le config.txt :
myString_1=Hello
myString_2=ArduinoGetStarted.com
myInt_1=2
myInt_2=-105
myFloat_1=0.74
myFloat_2=-46.08
- Connectez la carte Micro SD au PC via le lecteur de carte SD USB 3.0
- Assurez-vous que la carte Micro SD est formatée en FAT16 ou FAT32 (cherchez sur Google)
- Copiez le fichier config.txt dans le répertoire racine de la carte Micro SD
- Déconnectez la carte Micro SD du PC
- Connectez la carte Micro SD à l'Arduino via le module de carte Micro SD conformément au schéma de câblage ci-dessus
- Copiez le code ci-dessous et ouvrez-le avec l'IDE Arduino
/*
* Ce code Arduino a été développé par newbiely.fr
* Ce code Arduino est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino/arduino-read-config-from-sd-card
*/
#include <SD.h>
#define PIN_SPI_CS 4
#define FILE_NAME "config.txt"
#define KEY_MAX_LENGTH 30 // change it if key is longer
#define VALUE_MAX_LENGTH 30 // change it if value is longer
// variables
int myInt_1;
int myInt_2;
float myFloat_1;
float myFloat_2;
String myString_1;
String myString_2;
void setup() {
Serial.begin(9600);
if (!SD.begin(PIN_SPI_CS)) {
Serial.println(F("SD Card failed, or not present"));
while (1); // don't do anything more:
}
Serial.println(F("SD Card initialized."));
myInt_1 = SD_findInt(F("myInt_1"));
myInt_2 = SD_findInt(F("myInt_2"));
myFloat_1 = SD_findFloat(F("myFloat_1"));
myFloat_2 = SD_findFloat(F("myFloat_2"));
myString_1 = SD_findString(F("myString_1"));
myString_2 = SD_findString(F("myString_2"));
Serial.print(F("myInt_1 = "));
Serial.println(myInt_1);
Serial.print(F("myInt_2 = "));
Serial.println(myInt_2);
Serial.print(F("myFloat_1 = "));
Serial.println(myFloat_1);
Serial.print(F("myFloat_2 = "));
Serial.println(myFloat_2);
Serial.print(F("myString_1 = "));
Serial.println(myString_1);
Serial.print(F("myString_2 = "));
Serial.println(myString_2);
}
void loop() {
}
bool SD_available(const __FlashStringHelper * key) {
char value_string[VALUE_MAX_LENGTH];
int value_length = SD_findKey(key, value_string);
return value_length > 0;
}
int SD_findInt(const __FlashStringHelper * key) {
char value_string[VALUE_MAX_LENGTH];
int value_length = SD_findKey(key, value_string);
return HELPER_ascii2Int(value_string, value_length);
}
float SD_findFloat(const __FlashStringHelper * key) {
char value_string[VALUE_MAX_LENGTH];
int value_length = SD_findKey(key, value_string);
return HELPER_ascii2Float(value_string, value_length);
}
String SD_findString(const __FlashStringHelper * key) {
char value_string[VALUE_MAX_LENGTH];
int value_length = SD_findKey(key, value_string);
return HELPER_ascii2String(value_string, value_length);
}
int SD_findKey(const __FlashStringHelper * key, char * value) {
File configFile = SD.open(FILE_NAME);
if (!configFile) {
Serial.print(F("SD Card: error on opening file "));
Serial.println(FILE_NAME);
return;
}
char key_string[KEY_MAX_LENGTH];
char SD_buffer[KEY_MAX_LENGTH + VALUE_MAX_LENGTH + 1]; // 1 is = character
int key_length = 0;
int value_length = 0;
// Flash string to string
PGM_P keyPoiter;
keyPoiter = reinterpret_cast<PGM_P>(key);
byte ch;
do {
ch = pgm_read_byte(keyPoiter++);
if (ch != 0)
key_string[key_length++] = ch;
} while (ch != 0);
// check line by line
while (configFile.available()) {
int buffer_length = configFile.readBytesUntil('\n', SD_buffer, 100);
if (SD_buffer[buffer_length - 1] == '\r')
buffer_length--; // trim the \r
if (buffer_length > (key_length + 1)) { // 1 is = character
if (memcmp(SD_buffer, key_string, key_length) == 0) { // equal
if (SD_buffer[key_length] == '=') {
value_length = buffer_length - key_length - 1;
memcpy(value, SD_buffer + key_length + 1, value_length);
break;
}
}
}
}
configFile.close(); // close the file
return value_length;
}
int HELPER_ascii2Int(char *ascii, int length) {
int sign = 1;
int number = 0;
for (int i = 0; i < length; i++) {
char c = *(ascii + i);
if (i == 0 && c == '-')
sign = -1;
else {
if (c >= '0' && c <= '9')
number = number * 10 + (c - '0');
}
}
return number * sign;
}
float HELPER_ascii2Float(char *ascii, int length) {
int sign = 1;
int decimalPlace = 0;
float number = 0;
float decimal = 0;
for (int i = 0; i < length; i++) {
char c = *(ascii + i);
if (i == 0 && c == '-')
sign = -1;
else {
if (c == '.')
decimalPlace = 1;
else if (c >= '0' && c <= '9') {
if (!decimalPlace)
number = number * 10 + (c - '0');
else {
decimal += ((float)(c - '0') / pow(10.0, decimalPlace));
decimalPlace++;
}
}
}
}
return (number + decimal) * sign;
}
String HELPER_ascii2String(char *ascii, int length) {
String str;
str.reserve(length);
str = "";
for (int i = 0; i < length; i++) {
char c = *(ascii + i);
str += String(c);
}
return str;
}
- Cliquez sur le bouton Upload dans l'IDE Arduino pour charger le code sur Arduino
- Voir le résultat sur le moniteur série.
COM6
SD Card initialized.
myInt_1 = 2
myInt_2 = -105
myFloat_1 = 0.74
myFloat_2 = -46.08
myString_1 = Hello
myString_2 = ArduinoGetStarted.com
Autoscroll
Clear output
9600 baud
Newline
- Le moniteur série affiche les valeurs des variables qui sont identiques aux valeurs enregistrées sur la carte micro SD.
Vous pouvez maintenant modifier le code pour ajouter plus de variables.
※ NOTE THAT:
Le code ci-dessus ne tient pas compte de l'ordre des paires clé-valeur. Il recherchera la clé depuis le début jusqu'à la fin du fichier jusqu'à ce que la clé soit trouvée.