Arduino - DHT11 - OLED
Dans ce tutoriel, nous allons apprendre à lire la température et l'humidité à partir du module DHT11 et à les afficher sur un OLED.
Préparation du matériel
Or you can buy the following sensor kits:
| 1 | × | DIYables Sensor Kit (30 sensors/displays) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgation : Certains des liens fournis dans cette section sont des liens affiliés Amazon. Nous pouvons recevoir une commission pour tout achat effectué via ces liens, sans coût supplémentaire pour vous. Nous vous remercions de votre soutien.
À propos de l'écran OLED, Capteur de Température et d'Humidité DHT11
Si vous ne connaissez pas l'écran OLED et le capteur d'humidité et de température DHT11 (brochage, fonctionnement, programmation...), découvrez-les dans les tutoriels suivants :
- Arduino - OLED tutorial
- Arduino - DHT11 tutorial
Diagramme de câblage
This image is created using Fritzing. Click to enlarge image
Code Arduino - Capteur DHT11 - OLED
/*
* Ce code Arduino a été développé par newbiely.fr
* Ce code Arduino est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino/arduino-dht11-oled
*/
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <DHT.h>
#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels
#define DHT11_PIN 2 // pin connected to DHT11 sensor
Adafruit_SSD1306 oled(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1); // create SSD1306 display object connected to I2C
DHT dht11(DHT11_PIN, DHT11);
String displayString;
void setup() {
Serial.begin(9600);
// initialize OLED display with address 0x3C for 128x64
if (!oled.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
Serial.println(F("SSD1306 allocation failed"));
while (true);
}
delay(2000); // wait for initializing
oled.clearDisplay(); // clear display
oled.setTextSize(2); // text size
oled.setTextColor(WHITE); // text color
oled.setCursor(0, 10); // position to display
dht11.begin(); // initialize DHT11 the temperature and humidity sensor
displayString.reserve(10); // to avoid fragmenting memory when using String
}
void loop() {
float humi = dht11.readHumidity(); // read humidity
float tempC = dht11.readTemperature(); // read temperature
// check if any reads failed
if (isnan(humi) || isnan(tempC)) {
displayString = "Failed";
} else {
displayString = String(tempC, 1); // one decimal places
displayString += "°C";
displayString += String(humi, 1); // one decimal places
displayString += "%";
}
Serial.println(displayString); // print the temperature in Celsius to Serial Monitor
oledDisplayCenter(displayString); // display temperature and humidity on OLED
}
void oledDisplayCenter(String text) {
int16_t x1;
int16_t y1;
uint16_t width;
uint16_t height;
oled.getTextBounds(text, 0, 0, &x1, &y1, &width, &height);
// display on horizontal and vertical center
oled.clearDisplay(); // clear display
oled.setCursor((SCREEN_WIDTH - width) / 2, (SCREEN_HEIGHT - height) / 2);
oled.println(text); // text to display
oled.display();
}
Étapes rapides
- Ouvrez Arduino IDE sur votre PC.
- Accédez à l'icône Libraries dans la barre gauche de l'Arduino IDE.
- Recherchez "SSD1306", puis trouvez la bibliothèque SSD1306 par Adafruit
- Cliquez sur le bouton Install pour installer la bibliothèque.
- On vous demandera d'installer d'autres dépendances de bibliothèque.
- Cliquez sur le bouton Install All pour installer toutes les dépendances de bibliothèque.
- Recherchez « DHT », puis trouvez la bibliothèque de capteurs DHT par Adafruit
- Cliquez sur le bouton Install pour installer la bibliothèque.
- On vous demandera d'installer d'autres dépendances de bibliothèques.
- Cliquez sur le bouton Install All pour toutes les dépendances de la bibliothèque.
- Copiez le code ci-dessus et ouvrez-le avec l'IDE Arduino
- Cliquez sur le bouton Upload de l'IDE Arduino pour charger le code sur Arduino
- Placez le capteur dans l'eau chaude et froide, ou saisissez le capteur avec votre main
- Observez le résultat sur l'OLED et le moniteur série
※ NOTE THAT:
Le code ci-dessus aligne automatiquement le texte au centre horizontal et vertical sur l'affichage OLED.