ESP32 - Moteur pas à pas et interrupteur de fin de course
Dans ce tutoriel ESP32, nous explorerons comment utiliser l'ESP32, un interrupteur de fin de course, le pilote L298N et un moteur pas à pas. Plus précisément, nous aborderons :
- Arrêt du moteur pas à pas lorsqu'un interrupteur de fin de course est touché.
- Changement de direction du moteur pas à pas lorsqu'un interrupteur de fin de course est touché.
- Changement de direction du moteur pas à pas lorsque deux interrupteurs de fin de course sont touchés.
Ces sujets vous permettront de créer des applications de mouvement contrôlées et polyvalentes avec votre ESP32.
Préparation du matériel
Or you can buy the following sensor kits:
| 1 | × | DIYables Sensor Kit (30 sensors/displays) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgation : Certains des liens fournis dans cette section sont des liens affiliés Amazon. Nous pouvons recevoir une commission pour tout achat effectué via ces liens, sans coût supplémentaire pour vous. Nous vous remercions de votre soutien.
À propos du moteur pas à pas et de l'interrupteur de fin de course
Si vous ne connaissez pas le moteur pas à pas et l'interrupteur de fin de course (brochage, fonctionnement, programmation...), renseignez-vous à leur sujet dans les tutoriels suivants :
- ESP32 - Limit Switch tutorial
- ESP32 - Controls Stepper Motor tutorial
Diagramme de câblage
Ce tutoriel fournit les codes ESP32 pour deux cas : un moteur pas à pas + un interrupteur de fin de course, un moteur pas à pas + deux interrupteurs de fin de course.
- Schéma de câblage entre le moteur pas à pas et un interrupteur de fin de course
This image is created using Fritzing. Click to enlarge image
Si vous ne savez pas comment alimenter l'ESP32 et d'autres composants, vous pouvez trouver des conseils dans le tutoriel suivant : Comment alimenter l'ESP32.
- Schéma de câblage entre le moteur pas à pas et deux interrupteurs de fin de course.
This image is created using Fritzing. Click to enlarge image
※ NOTE THAT:
En fonction du moteur pas à pas, la connexion des câbles entre le moteur pas à pas et le L298N peut être différente. Veuillez consulter attentivement ce tutoriel ESP32 - Moteur Pas à Pas pour voir comment connecter le moteur pas à pas au pilote de moteur L298N.
Code ESP32 - Arrêter un moteur pas à pas avec un interrupteur de fin de course
Il existe plusieurs façons de faire arrêter un moteur pas à pas :
- Appelez la fonction stepper.stop() : Cette méthode ne permet PAS d'arrêter le moteur pas à pas immédiatement, mais progressivement.
- Ne pas appeler la fonction stepper.run() : Cette méthode arrête le moteur pas à pas immédiatement.
Le code ci-dessous fait tourner un moteur pas à pas indéfiniment et s'arrête immédiatement lorsqu'un interrupteur de fin de course est touché.
/*
* Ce code ESP32 a été développé par newbiely.fr
* Ce code ESP32 est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/esp32/esp32-stepper-motor-and-limit-switch
*/
#include <ezButton.h>
#include <AccelStepper.h>
#define MAX_POSITION 0x7FFFFFFF // maximum of position we can set (long type)
ezButton limitSwitch(25); // ESP32 pin: GPIO25
AccelStepper stepper(AccelStepper::FULL4WIRE, 19, 18, 17, 16); // ESP32 pin: GPIO19, GPIO18, GPIO17, GPIO16
bool isStopped = false;
void setup() {
Serial.begin(9600);
limitSwitch.setDebounceTime(50); // set debounce time to 50 milliseconds
stepper.setMaxSpeed(500.0); // set the maximum speed
stepper.setAcceleration(50.0); // set acceleration
stepper.setSpeed(100); // set initial speed
stepper.setCurrentPosition(0); // set position
stepper.moveTo(MAX_POSITION);
}
void loop() {
limitSwitch.loop(); // MUST call the loop() function first
if (limitSwitch.isPressed()) {
Serial.println(F("The limit switch: TOUCHED"));
isStopped = true;
}
if (isStopped == false) {
// without this part, the move will stop after reaching maximum position
if (stepper.distanceToGo() == 0) { // if motor moved to the maximum position
stepper.setCurrentPosition(0); // reset position to 0
stepper.moveTo(MAX_POSITION); // move the motor to maximum position again
}
stepper.run(); // MUST be called in loop() function
} else {
// without calling stepper.run() function, motor stops immediately
// NOTE: stepper.stop() function does NOT stops motor immediately
Serial.println(F("The stepper motor is STOPPED"));
}
}
Étapes rapides
- Si c'est la première fois que vous utilisez l'ESP32, consultez comment configurer l'environnement pour l'ESP32 sur Arduino IDE.
- Réalisez le câblage comme sur l'image ci-dessus.
- Connectez la carte ESP32 à votre PC via un câble micro USB.
- Ouvrez Arduino IDE sur votre PC.
- Sélectionnez la bonne carte ESP32 (par exemple, Module de développement ESP32) et le port COM.
- Connectez l'ESP32 au PC via un câble USB.
- Ouvrez Arduino IDE, sélectionnez la bonne carte et le bon port.
- Cliquez sur l'icône Libraries dans la barre latérale gauche de l'Arduino IDE.
- Recherchez "ezButton", puis trouvez la bibliothèque du bouton par ArduinoGetStarted.com.
- Cliquez sur le bouton Install pour installer la bibliothèque ezButton.
- Recherchez "AccelStepper", puis trouvez la bibliothèque AccelStepper de Mike McCauley.
- Cliquez sur le bouton Install pour installer la bibliothèque AccelStepper.
- Copiez le code ci-dessus et ouvrez-le avec l'IDE Arduino
- Cliquez sur le bouton Upload de l'IDE Arduino pour téléverser le code sur l'ESP32
- Si le câblage est correct, vous verrez le moteur tourner dans le sens des aiguilles d'une montre.
- Touchez l'interrupteur de fin de course
- Vous verrez que le moteur s'arrête immédiatement
- Le résultat sur le moniteur série apparaît comme ci-dessous
COM6
The limit switch: TOUCHED
The stepper motor is STOPPED
The stepper motor is STOPPED
The stepper motor is STOPPED
The stepper motor is STOPPED
Autoscroll
Clear output
9600 baud
Newline
Explication du code
Vous pouvez trouver l'explication dans la ligne de commentaires du code Arduino ci-dessus.
Code ESP32 - Changer la direction d'un moteur pas à pas par un interrupteur de fin de course
Le code ci-dessous permet de faire tourner un moteur pas à pas indéfiniment et de changer sa direction lorsqu'un interrupteur de fin de course est touché.
/*
* Ce code ESP32 a été développé par newbiely.fr
* Ce code ESP32 est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/esp32/esp32-stepper-motor-and-limit-switch
*/
#include <ezButton.h>
#include <AccelStepper.h>
#define DIRECTION_CCW -1
#define DIRECTION_CW 1
#define MAX_POSITION 0x7FFFFFFF // maximum of position we can set (long type)
ezButton limitSwitch(25); // ESP32 pin: GPIO25
AccelStepper stepper(AccelStepper::FULL4WIRE, 19, 18, 17, 16); // ESP32 pin: GPIO19, GPIO18, GPIO17, GPIO16
int direction = DIRECTION_CW;
long targetPos = 0;
void setup() {
Serial.begin(9600);
limitSwitch.setDebounceTime(50); // set debounce time to 50 milliseconds
stepper.setMaxSpeed(500.0); // set the maximum speed
stepper.setAcceleration(50.0); // set acceleration
stepper.setSpeed(100); // set initial speed
stepper.setCurrentPosition(0); // set position
targetPos = direction * MAX_POSITION;
stepper.moveTo(targetPos);
}
void loop() {
limitSwitch.loop(); // MUST call the loop() function first
if (limitSwitch.isPressed()) {
Serial.println(F("The limit switch: TOUCHED"));
direction *= -1; // change direction
Serial.print(F("The direction -> "));
if (direction == DIRECTION_CW)
Serial.println(F("CLOCKWISE"));
else
Serial.println(F("ANTI-CLOCKWISE"));
targetPos = direction * MAX_POSITION;
stepper.setCurrentPosition(0); // set position
stepper.moveTo(targetPos);
}
// without this part, the move will stop after reaching maximum position
if (stepper.distanceToGo() == 0) { // if motor moved to the maximum position
stepper.setCurrentPosition(0); // reset position to 0
stepper.moveTo(targetPos); // move the motor to maximum position again
}
stepper.run(); // MUST be called in loop() function
}
Étapes rapides
- Copiez le code ci-dessus et ouvrez-le avec l'IDE Arduino
- Cliquez sur le bouton Upload de l'IDE Arduino pour charger le code sur l'ESP32
- Si le câblage est correct, vous verrez le moteur tourner dans le sens des aiguilles d'une montre.
- Touchez l'interrupteur de fin de course
- Vous verrez la direction du moteur pas à pas changer en sens antihoraire
- Touchez à nouveau l'interrupteur de fin de course
- Vous verrez la direction du moteur pas à pas changer en sens horaire
- Le résultat sur le moniteur série apparaît comme ci-dessous
COM6
The limit switch: TOUCHED
The direction -> ANTI-CLOCKWISE
The limit switch: TOUCHED
The direction -> CLOCKWISE
Autoscroll
Clear output
9600 baud
Newline
Code ESP32 - Changer la direction du moteur pas à pas avec deux interrupteurs de fin de course
Le code ci-dessous permet de faire tourner un moteur pas à pas indéfiniment et de changer sa direction lorsque l'un des deux interrupteurs de fin de course est actionné.
/*
* Ce code ESP32 a été développé par newbiely.fr
* Ce code ESP32 est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/esp32/esp32-stepper-motor-and-limit-switch
*/
#include <ezButton.h>
#include <AccelStepper.h>
#define DIRECTION_CCW -1
#define DIRECTION_CW 1
#define STATE_CHANGE_DIR 1
#define STATE_MOVE 2
#define STATE_MOVING 3
#define MAX_POSITION 0x7FFFFFFF // maximum of position we can set (long type)
ezButton limitSwitch_1(25); // ESP32 pin: GPIO25
ezButton limitSwitch_2(26); // ESP32 pin: GPIO26
AccelStepper stepper(AccelStepper::FULL4WIRE, 19, 18, 17, 16); // ESP32 pin: GPIO19, GPIO18, GPIO17, GPIO16
int stepperState = STATE_MOVE;
int direction = DIRECTION_CW;
long targetPos = 0;
void setup() {
Serial.begin(9600);
limitSwitch_1.setDebounceTime(50); // set debounce time to 50 milliseconds
limitSwitch_2.setDebounceTime(50); // set debounce time to 50 milliseconds
stepper.setMaxSpeed(500.0); // set the maximum speed
stepper.setAcceleration(50.0); // set acceleration
stepper.setSpeed(100); // set initial speed
stepper.setCurrentPosition(0); // set position
}
void loop() {
limitSwitch_1.loop(); // MUST call the loop() function first
limitSwitch_2.loop(); // MUST call the loop() function first
if (limitSwitch_1.isPressed()) {
stepperState = STATE_CHANGE_DIR;
Serial.println(F("The limit switch 1: TOUCHED"));
}
if (limitSwitch_2.isPressed()) {
stepperState = STATE_CHANGE_DIR;
Serial.println(F("The limit switch 2: TOUCHED"));
}
switch (stepperState) {
case STATE_CHANGE_DIR:
direction *= -1; // change direction
Serial.print(F("The direction -> "));
if (direction == DIRECTION_CW)
Serial.println(F("CLOCKWISE"));
else
Serial.println(F("ANTI-CLOCKWISE"));
stepperState = STATE_MOVE; // after changing direction, go to the next state to move the motor
break;
case STATE_MOVE:
targetPos = direction * MAX_POSITION;
stepper.setCurrentPosition(0); // set position
stepper.moveTo(targetPos);
stepperState = STATE_MOVING; // after moving, go to the next state to keep the motor moving infinity
break;
case STATE_MOVING: // without this state, the move will stop after reaching maximum position
if (stepper.distanceToGo() == 0) { // if motor moved to the maximum position
stepper.setCurrentPosition(0); // reset position to 0
stepper.moveTo(targetPos); // move the motor to maximum position again
}
break;
}
stepper.run(); // MUST be called in loop() function
}
Étapes rapides
- Copiez le code ci-dessus et ouvrez-le avec Arduino IDE
- Cliquez sur le bouton Upload dans Arduino IDE pour téléverser le code vers ESP32
- Si le câblage est correct, vous verrez le moteur tourner dans le sens horaire.
- Touchez l'interrupteur de limite 1
- Vous verrez que la direction du moteur pas à pas est modifiée en sens antihoraire
- Touchez l'interrupteur de limite 2
- Vous verrez que la direction du moteur pas à pas est modifiée en sens horaire
- Le résultat sur le moniteur série apparaît comme ci-dessous
COM6
The limit switch 1: TOUCHED
The direction -> ANTI-CLOCKWISE
The limit switch 2: TOUCHED
The direction -> CLOCKWISE
Autoscroll
Clear output
9600 baud
Newline