Arduino UNO R4 - Clavier 4x4
Ce tutoriel vous apprendra comment utiliser un Arduino UNO R4 avec un clavier 4x4. Nous aborderons les étapes suivantes :
- Connexion d'un clavier 4x4 à l'Arduino UNO R4.
- Programmation de l'Arduino UNO R4 pour lire quelle touche est pressée sur le clavier 4x4.
- Vérification d'un mot de passe saisi avec le clavier 4x4.
Préparation du matériel
Ou vous pouvez acheter les kits suivants:
| 1 | × | Kit de Démarrage DIYables STEM V4 IoT (Arduino inclus) | |
| 1 | × | Kit de Capteurs DIYables (30 capteurs/écrans) | |
| 1 | × | Kit de Capteurs DIYables (18 capteurs/écrans) |
Divulgation : Certains des liens fournis dans cette section sont des liens affiliés Amazon. Nous pouvons recevoir une commission pour tout achat effectué via ces liens, sans coût supplémentaire pour vous. Nous vous remercions de votre soutien.
À propos du pavé numérique 4x4
Le pavé numérique comporte 16 touches à membranes disposées en rangées et en colonnes, connues sous le nom de matrice. Chaque bouton est appelé une touche.
Schéma des broches
Un clavier matriciel 4x4 possède 8 broches, réparties en deux catégories : lignes et colonnes.
- 4 broches sont destinées aux lignes (R1, R2, R3, R4).
- 4 broches sont destinées aux colonnes (C1, C2, C3, C4).
Diagramme de câblage
Cette image a été créée avec Fritzing. Cliquez pour agrandir l'image.
Code Arduino UNO R4
#include <DIYables_Keypad.h> // DIYables_Keypad library
const int ROW_NUM = 4; // four rows
const int COLUMN_NUM = 4; // four columns
char keys[ROW_NUM][COLUMN_NUM] = {
{'1','2','3', 'A'},
{'4','5','6', 'B'},
{'7','8','9', 'C'},
{'*','0','#', 'D'}
};
byte pin_rows[ROW_NUM] = {9, 8, 7, 6}; //connect to the row pinouts of the keypad
byte pin_column[COLUMN_NUM] = {5, 4, 3, 2}; //connect to the column pinouts of the keypad
DIYables_Keypad keypad = DIYables_Keypad( makeKeymap(keys), pin_rows, pin_column, ROW_NUM, COLUMN_NUM );
void setup(){
Serial.begin(9600);
delay(1000);
Serial.println("Keypad 4x4 example");
}
void loop(){
char key = keypad.getKey();
if (key){
Serial.println(key);
}
}
Étapes rapides
Suivez ces instructions étape par étape :
- Si c'est la première fois que vous utilisez l'Arduino Uno R4 WiFi/Minima, consultez le tutoriel sur Arduino UNO R4 - Installation du logiciel..
- Connectez le clavier 4x4 à l'Arduino Uno R4 selon le diagramme fourni.
- Branchez l'Arduino Uno R4 à votre ordinateur à l'aide d'un câble USB.
- Ouvrez l'IDE Arduino sur votre ordinateur.
- Sélectionnez la carte Arduino Uno R4 appropriée (par exemple, Arduino Uno R4 WiFi) et le port COM.
- Accédez à l'icône Libraries sur le côté gauche de l'IDE Arduino.
- Tapez DIYables_Keypad dans la barre de recherche, et recherchez la bibliothèque keypad par DIYables.io.
- Cliquez sur le bouton Install pour installer la bibliothèque keypad.
- Copiez le code ci-dessus et ouvrez-le avec l'IDE Arduino.
- Cliquez sur le bouton Upload dans l'IDE Arduino pour téléverser le code sur l'Arduino UNO R4.
- Ouvrez le moniteur série.
- Appuyez sur quelques touches du clavier.
- Vérifiez les résultats dans le moniteur série.
COM6
1
2
3
4
A
B
C
*
#
Autoscroll
Clear output
9600 baud
Newline
Clavier numérique et mot de passe
Une utilisation courante d'un clavier numérique est la saisie d'un mot de passe. Dans ce cas, nous utilisons deux touches spéciales :
- Une touche pour commencer ou recommencer la saisie du mot de passe. Par exemple, la touche «*».
- Une touche pour terminer la saisie du mot de passe. Par exemple, la touche «#».
Le mot de passe sera composé des autres touches, en excluant les deux touches spéciales. Lorsqu'une touche est enfoncée :
- Si la touche n'est ni '*' ni '#', ajoutez la touche au mot de passe que l'utilisateur est en train de saisir.
- Si la touche est '#', vérifiez si le mot de passe saisi correspond au mot de passe défini, puis effacez le mot de passe saisi.
- Si la touche est '*', effacez le mot de passe saisi.
Clavier numérique - Code d'accès
/*
* Ce code Arduino UNO R4 a été développé par newbiely.fr
* Ce code Arduino UNO R4 est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino-uno-r4/arduino-uno-r4-keypad-4x4
*/
#include <DIYables_Keypad.h> // DIYables_Keypad library
const int ROW_NUM = 4; // four rows
const int COLUMN_NUM = 4; // four columns
char keys[ROW_NUM][COLUMN_NUM] = {
{'1','2','3', 'A'},
{'4','5','6', 'B'},
{'7','8','9', 'C'},
{'*','0','#', 'D'}
};
byte pin_rows[ROW_NUM] = {9, 8, 7, 6}; // connect to the row pinouts of the keypad
byte pin_column[COLUMN_NUM] = {5, 4, 3, 2}; // connect to the column pinouts of the keypad
DIYables_Keypad keypad = DIYables_Keypad( makeKeymap(keys), pin_rows, pin_column, ROW_NUM, COLUMN_NUM );
const String password = "1234A"; // change your password here
String input_password;
void setup(){
Serial.begin(9600);
Serial.println("Keypad 4x4 password");
input_password.reserve(32); // maximum input characters is 33, change if needed
}
void loop(){
char key = keypad.getKey();
if (key){
Serial.println(key);
if(key == '*') {
input_password = ""; // clear input password
} else if(key == '#') {
if(password == input_password) {
Serial.println("password is correct");
// DO YOUR WORK HERE
} else {
Serial.println("password is incorrect, try again");
}
input_password = ""; // clear input password
} else {
input_password += key; // append new character to input password string
}
}
}
- Exécutez le code fourni ci-dessus.
- Ouvrez le moniteur série.
- Saisissez les touches « 1234BC » puis appuyez sur « # ».
- Saisissez les touches « 1234A » puis appuyez sur « # ».
- Vérifiez les résultats sur le moniteur série.
COM6
password is incorrect, try again
password is correct
Autoscroll
Clear output
9600 baud
Newline