Arduino UNO R4 - Joystick - Servomoteur
Dans ce guide, nous apprendrons comment utiliser un Arduino UNO R4 et un joystick pour contrôler deux servomoteurs ou un kit pan-tilt.
Un joystick possède deux potentiomètres, placés à des angles droits les uns par rapport aux autres, connus sous les noms d'axes X et Y. Ces potentiomètres produisent des signaux, appelés valeurs X et Y, qui sortent des broches VRX et VRY du joystick. Nous utilisons ces signaux pour contrôler deux servomoteurs : la valeur X déplace le servomoteur n° 1 et la valeur Y déplace le servomoteur n° 2. Lorsque vous les utilisez avec un kit pan-tilt, les deux servomoteurs fonctionnent ensemble pour se déplacer dans les trois dimensions.
Il y a deux exemples de la façon dont l'application peut être utilisée :
- Cas d'utilisation 1 : Les servomoteurs tournent en fonction de la façon dont le joystick est déplacé:
- Les angles de déplacement des servomoteurs correspondent aux déplacements horizontaux (X) et verticaux (Y) du joystick.
- Relâcher le joystick fait revenir le joystick et les servomoteurs à leur position de départ.
- Cas d'utilisation 2 : Contrôlez les servomoteurs avec le joystick pour différentes directions:
- Pousser le joystick vers la gauche fait tourner le servomoteur n°1 dans le sens des aiguilles d'une montre.
- Pousser le joystick vers la droite fait tourner le servomoteur n°1 dans le sens inverse des aiguilles d'une montre.
- Pousser le joystick vers le haut fait tourner le servomoteur n°2 dans le sens des aiguilles d'une montre.
- Pousser le joystick vers le bas fait tourner le servomoteur n°2 dans le sens inverse des aiguilles d'une montre.
- Relâcher le joystick ne réinitialise pas les servomoteurs.
- En appuyant sur le bouton du joystick, les servomoteurs se réinitialisent au centre.
- Si c'est la première fois que vous utilisez l'Arduino Uno R4 WiFi/Minima, reportez-vous au tutoriel sur Arduino UNO R4 - Installation du logiciel..
- Connectez l'Arduino Uno R4 au moteur servo et au joystick selon le schéma fourni.
- Connectez la carte Arduino Uno R4 à votre ordinateur à l'aide d'un câble USB.
- Lancez l'IDE Arduino sur votre ordinateur.
- Sélectionnez la carte Arduino Uno R4 appropriée (par exemple Arduino Uno R4 WiFi) et le port COM.
- Copiez le code fourni et ouvrez-le dans l'IDE Arduino.
- Cliquez sur le bouton Upload dans l'IDE Arduino pour transférer le code vers votre Arduino UNO R4.
- Ouvrez le Moniteur Série.
- Déplacez le joystick dans n'importe quelle direction.
- Observez la rotation du servomoteur.
- Vérifiez le résultat sur le Moniteur Série.
- Accédez à l'icône Libraries sur le côté gauche de l'IDE Arduino.
- Saisissez ezButton dans la zone de recherche, et recherchez la bibliothèque de boutons par ArduinoGetStarted.com.
- Appuyez sur le bouton Install pour ajouter la bibliothèque ezButton.
- Copiez le code fourni et ouvrez-le dans l'IDE Arduino.
- Cliquez sur le bouton Upload dans l'IDE Arduino pour envoyer le code à l'Arduino UNO R4.
- Ouvrez le moniteur série.
- Déplacez le joystick dans n'importe quelle direction.
- Observez le servomoteur en rotation.
- Vérifiez les résultats sur le moniteur série.
Préparation du matériel
Ou vous pouvez acheter les kits suivants:
| 1 | × | Kit de Démarrage DIYables STEM V4 IoT (Arduino inclus) | |
| 1 | × | Kit de Capteurs DIYables (30 capteurs/écrans) | |
| 1 | × | Kit de Capteurs DIYables (18 capteurs/écrans) |
Divulgation : Certains des liens fournis dans cette section sont des liens affiliés Amazon. Nous pouvons recevoir une commission pour tout achat effectué via ces liens, sans coût supplémentaire pour vous. Nous vous remercions de votre soutien.
À propos du joystick et du servomoteur
Si vous n'êtes pas familier avec les détails des joysticks et des servomoteurs, tels que le brochage, le fonctionnement et la programmation, veuillez consulter les tutoriels suivants pour en savoir plus.
Diagramme de câblage
Cette image a été créée avec Fritzing. Cliquez pour agrandir l'image.
Code Arduino UNO R4
Arduino UNO R4 Code - Les servomoteurs tournent en fonction du déplacement du pouce du joystick
/*
* Ce code Arduino UNO R4 a été développé par newbiely.fr
* Ce code Arduino UNO R4 est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino-uno-r4/arduino-uno-r4-joystick-servo-motor
*/
#include <Servo.h>
#define VRX_PIN A0 // The Arduino UNO R4 pin connected to VRX pin
#define VRY_PIN A1 // The Arduino UNO R4 pin connected to VRY pin
#define SERVO_X_PIN 9 // The Arduino UNO R4 pin connected to Servo motor 1
#define SERVO_Y_PIN 10 // The Arduino UNO R4 pin connected to Servo motor 2
Servo xServo; // create servo object to control a servo 1
Servo yServo; // create servo object to control a servo 2
void setup() {
Serial.begin(9600) ;
xServo.attach(SERVO_X_PIN);
yServo.attach(SERVO_Y_PIN);
}
void loop() {
// read analog X and Y analog values
int xValue = analogRead(VRX_PIN);
int yValue = analogRead(VRY_PIN);
int xAngle = map(xValue, 0, 1023, 0, 180); // scale it to the servo's angle (0 to 180)
int yAngle = map(yValue, 0, 1023, 0, 180); // scale it to the servo's angle (0 to 180)
xServo.write(xAngle); // rotate servo motor 1
yServo.write(yAngle); // rotate servo motor 2
// print data to Serial Monitor on Arduino IDE
Serial.print("Joystick: ");
Serial.print(xValue);
Serial.print(", ");
Serial.print(yValue);
Serial.print(" => Servo Motor: ");
Serial.print(xAngle);
Serial.print("°, ");
Serial.print(yAngle);
Serial.println("°");
}
Étapes rapides
Suivez ces instructions étape par étape :
COM6
Coming soon
Autoscroll
Clear output
9600 baud
Newline
Code Arduino UNO R4 - Utiliser le joystick pour commander des servomoteurs
/*
* Ce code Arduino UNO R4 a été développé par newbiely.fr
* Ce code Arduino UNO R4 est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino-uno-r4/arduino-uno-r4-joystick-servo-motor
*/
#include <Servo.h>
#include <ezButton.h>
#define VRX_PIN A0 // The Arduino UNO R4 pin connected to VRX pin
#define VRY_PIN A1 // The Arduino UNO R4 pin connected to VRY pin
#define SW_PIN A5 // The Arduino UNO R4 pin connected to SW pin
#define SERVO_X_PIN 9 // The Arduino UNO R4 pin connected to Servo motor 1
#define SERVO_Y_PIN 10 // The Arduino UNO R4 pin connected to Servo motor 2
#define COMMAND_NO 0x00
#define COMMAND_LEFT 0x01
#define COMMAND_RIGHT 0x02
#define COMMAND_UP 0x04
#define COMMAND_DOWN 0x08
#define LEFT_THRESHOLD 400
#define RIGHT_THRESHOLD 800
#define UP_THRESHOLD 400
#define DOWN_THRESHOLD 800
#define UPDATE_INTERVAL 100 // 100ms
ezButton button(SW_PIN);
Servo xServo; // create servo object to control a servo 1
Servo yServo; // create servo object to control a servo 2
int xValue = 0 ; // To store value of the X axis
int yValue = 0 ; // To store value of the Y axis
int xAngle = 90; // the center position of servo #1
int yAngle = 90; // the center position of servo #2
int command = COMMAND_NO;
unsigned long lastUpdateTime = 0;
void setup() {
Serial.begin(9600) ;
xServo.attach(SERVO_X_PIN);
yServo.attach(SERVO_Y_PIN);
button.setDebounceTime(50); // set debounce time to 50 milliseconds
}
void loop() {
button.loop(); // MUST call the loop() function first
if (millis() - lastUpdateTime > UPDATE_INTERVAL) {
lastUpdateTime = millis() ;
// read analog X and Y analog values
xValue = analogRead(VRX_PIN);
yValue = analogRead(VRY_PIN);
// converts the analog value to commands
// reset commands
command = COMMAND_NO;
// check left/right commands
if (xValue < LEFT_THRESHOLD)
command = command | COMMAND_LEFT;
else if (xValue > RIGHT_THRESHOLD)
command = command | COMMAND_RIGHT;
// check up/down commands
if (yValue < UP_THRESHOLD)
command = command | COMMAND_UP;
else if (yValue > DOWN_THRESHOLD)
command = command | COMMAND_DOWN;
// NOTE: AT A TIME, THERE MAY BE NO COMMAND, ONE COMMAND OR TWO COMMANDS
// print command to serial and process command
if (command & COMMAND_LEFT) {
Serial.println("COMMAND LEFT");
xAngle--;
}
if (command & COMMAND_RIGHT) {
Serial.println("COMMAND RIGHT");
xAngle++;
}
if (command & COMMAND_UP) {
Serial.println("COMMAND UP");
yAngle--;
}
if (command & COMMAND_DOWN) {
Serial.println("COMMAND DOWN");
yAngle++;
}
}
if (button.isPressed()) {
Serial.println("The button is pressed");
xAngle = 90; // the center position of servo #1
yAngle = 90; // the center position of servo #2
}
xServo.write(xAngle); // rotate servo motor 1
yServo.write(yAngle); // rotate servo motor 2
// print data to Serial Monitor on Arduino IDE
Serial.print("Servo Motor's Angle: ");
Serial.print(xAngle);
Serial.print("°, ");
Serial.print(xAngle);
Serial.println("°");
}
Étapes rapides
COM6
Autoscroll
Clear output
9600 baud
Newline
Explication du code
Vérifiez les explications fournies dans les commentaires du code source !