Arduino UNO R4 - GPS
Ce tutoriel vous explique comment utiliser l'Arduino Uno R4 avec un module GPS. En détail, nous apprendrons à trouver les coordonnées GPS (longitude, latitude, altitude), la vitesse GPS (en kilomètres par heure) et la date et l'heure actuelles à partir d'un module GPS NEO-6M. Nous apprendrons également à calculer la distance entre notre position GPS actuelle et des coordonnées spécifiques, comme celles de Londres.
Préparation du matériel
Ou vous pouvez acheter les kits suivants:
| 1 | × | Kit de Démarrage DIYables STEM V4 IoT (Arduino inclus) | |
| 1 | × | Kit de Capteurs DIYables (30 capteurs/écrans) | |
| 1 | × | Kit de Capteurs DIYables (18 capteurs/écrans) |
Divulgation : Certains des liens fournis dans cette section sont des liens affiliés Amazon. Nous pouvons recevoir une commission pour tout achat effectué via ces liens, sans coût supplémentaire pour vous. Nous vous remercions de votre soutien.
À propos du module GPS NEO-6M
Schéma de brochage
Le module GPS NEO-6M possède 4 broches :
- Broche VCC : Reliez cette broche au VCC (5 V).
- Broche GND : Reliez cette broche au GND (0 V).
- Broche TX : Elle est utilisée pour la communication série. Reliez-la à la broche RX du port série (ou SoftwareSerial) sur l'Arduino UNO R4.
- Broche RX : Elle est utilisée pour la communication série. Reliez-la à la broche TX du port série (ou SoftwareSerial) sur l'Arduino UNO R4.
Diagramme de câblage
Cette image a été créée avec Fritzing. Cliquez pour agrandir l'image.
Veuillez noter que le schéma de câblage montré ci-dessus peut fonctionner, mais ce n'est pas recommandé. La broche TX de l'Arduino UNO R4 émet un signal de 5 V, tandis que la broche RX du module GPS ne peut supporter que 3,3 V. Pour des raisons de sécurité, vous devriez utiliser un diviseur de tension entre la broche TX de l'Arduino UNO R4 et la broche RX du module GPS. Cette configuration est illustrée dans le schéma ci-dessous.
Cette image a été créée avec Fritzing. Cliquez pour agrandir l'image.
Code Arduino UNO R4
Lecture des coordonnées GPS, de la vitesse (km/h) et de la date et de l'heure
/*
* Ce code Arduino UNO R4 a été développé par newbiely.fr
* Ce code Arduino UNO R4 est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino-uno-r4/arduino-uno-r4-gps
*/
#include <TinyGPS++.h>
#include <SoftwareSerial.h>
#define RX_PIN 4 // The Arduino UNO R4 pin connected to the TX of the GPS module
#define TX_PIN 3 // The Arduino UNO R4 pin connected to the RX of the GPS module
TinyGPSPlus gps; // the TinyGPS++ object
SoftwareSerial gpsSerial(RX_PIN, TX_PIN); // the serial interface to the GPS module
void setup() {
Serial.begin(9600);
gpsSerial.begin(9600); // Default baud of NEO-6M GPS module is 9600
Serial.println(F("Arduino - GPS module"));
}
void loop() {
if (gpsSerial.available() > 0) {
if (gps.encode(gpsSerial.read())) {
if (gps.location.isValid()) {
Serial.print(F("- latitude: "));
Serial.println(gps.location.lat());
Serial.print(F("- longitude: "));
Serial.println(gps.location.lng());
Serial.print(F("- altitude: "));
if (gps.altitude.isValid())
Serial.println(gps.altitude.meters());
else
Serial.println(F("INVALID"));
} else {
Serial.println(F("- location: INVALID"));
}
Serial.print(F("- speed: "));
if (gps.speed.isValid()) {
Serial.print(gps.speed.kmph());
Serial.println(F(" km/h"));
} else {
Serial.println(F("INVALID"));
}
Serial.print(F("- GPS date&time: "));
if (gps.date.isValid() && gps.time.isValid()) {
Serial.print(gps.date.year());
Serial.print(F("-"));
Serial.print(gps.date.month());
Serial.print(F("-"));
Serial.print(gps.date.day());
Serial.print(F(" "));
Serial.print(gps.time.hour());
Serial.print(F(":"));
Serial.print(gps.time.minute());
Serial.print(F(":"));
Serial.println(gps.time.second());
} else {
Serial.println(F("INVALID"));
}
Serial.println();
}
}
if (millis() > 5000 && gps.charsProcessed() < 10)
Serial.println(F("No GPS data received: check wiring"));
}
Étapes rapides
Suivez ces instructions étape par étape :
- Si c'est la première fois que vous utilisez l'Arduino Uno R4 WiFi/Minima, reportez-vous au tutoriel sur Arduino UNO R4 - Installation du logiciel..
- Reliez l'Arduino Uno R4 au module GPS selon le schéma fourni.
- Connectez la carte Arduino Uno R4 à votre ordinateur à l'aide d'un câble USB.
- Lancez l'IDE Arduino sur votre ordinateur.
- Sélectionnez la carte Arduino Uno R4 appropriée (par exemple, Arduino Uno R4 WiFi) et le port COM.
- Allez dans l'icône Libraries sur le côté gauche de l'IDE Arduino.
- Tapez TinyGPSPlus dans la boîte de recherche, puis cherchez la bibliothèque TinyGPSPlus de Mikal Hart.
- Cliquez sur le bouton Install pour ajouter la bibliothèque TinyGPSPlus.
- Copiez le code et ouvrez-le dans l'IDE Arduino.
- Cliquez sur le bouton Upload dans l'IDE Arduino pour téléverser le code sur l'Arduino UNO R4.
- Vérifiez le résultat dans le Moniteur série.
COM6
Autoscroll
Clear output
9600 baud
Newline
Calcul de la distance entre l’emplacement actuel et un emplacement prédéfini
Ce code calcule la distance qui vous sépare de Londres (latitude : 51,508131, longitude : -0,128002).
/*
* Ce code Arduino UNO R4 a été développé par newbiely.fr
* Ce code Arduino UNO R4 est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino-uno-r4/arduino-uno-r4-gps
*/
#include <TinyGPS++.h>
#include <SoftwareSerial.h>
#define RX_PIN 4 // The Arduino UNO R4 pin connected to the TX of the GPS module
#define TX_PIN 3 // The Arduino UNO R4 pin connected to the RX of the GPS module
TinyGPSPlus gps; // the TinyGPS++ object
SoftwareSerial gpsSerial(RX_PIN, TX_PIN); // the serial interface to the GPS module
const double LONDON_LAT = 51.508131;
const double LONDON_LON = -0.128002;
void setup() {
Serial.begin(9600);
gpsSerial.begin(9600); // Default baud of NEO-6M GPS module is 9600
Serial.println(F("Arduino - GPS module"));
}
void loop() {
if (gpsSerial.available() > 0) {
if (gps.encode(gpsSerial.read())) {
if (gps.location.isValid()) {
double latitude = gps.location.lat();
double longitude = gps.location.lng();
unsigned long distanceKm = TinyGPSPlus::distanceBetween(latitude, longitude, LONDON_LAT, LONDON_LON) / 1000;
Serial.print(F("- latitude: "));
Serial.println(latitude);
Serial.print(F("- longitude: "));
Serial.println(longitude);
Serial.print(F("- distance to London: "));
Serial.println(distanceKm);
} else {
Serial.println(F("- location: INVALID"));
}
Serial.println();
}
}
if (millis() > 5000 && gps.charsProcessed() < 10)
Serial.println(F("No GPS data received: check wiring"));
}
Étapes rapides
- Copiez le code et ouvrez-le dans l'IDE Arduino.
- Cliquez sur le bouton Upload dans l'IDE Arduino pour envoyer le code à l'Arduino UNO R4.
- Vérifiez le résultat sur le Moniteur Série.
COM6
Autoscroll
Clear output
9600 baud
Newline