Système de verrouillage de porte utilisant un mot de passe avec Arduino Nano ESP32
Ce tutoriel vous explique comment utiliser l'ESP32, un clavier et un verrou électromagnétique pour créer un système de verrouillage de porte. Les utilisateurs devront entrer un mot de passe via le clavier. Si le mot de passe est valide, l'Arduino Nano ESP32 contrôle le verrou électromagnétique pour déverrouiller la porte. Le tutoriel ajoute également en option un écran LCD pour plus de commodité. Le code de l'Arduino Nano ESP32 prend également en charge plusieurs mots de passe.
Préparation du matériel
Or you can buy the following sensor kits:
| 1 | × | DIYables Sensor Kit (30 sensors/displays) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgation : Certains des liens fournis dans cette section sont des liens affiliés Amazon. Nous pouvons recevoir une commission pour tout achat effectué via ces liens, sans coût supplémentaire pour vous. Nous vous remercions de votre soutien.
À propos du clavier, du verrouillage électromagnétique et de l'écran LCD
Nous disposons de tutoriels spécifiques sur le clavier numérique, le verrou électromagnétique et l'écran LCD. Chaque tutoriel contient des informations détaillées et des instructions étape par étape sur le brochage du matériel, le principe de fonctionnement, la connexion des fils à l'ESP32, le code Arduino Nano ESP32... Pour en savoir plus, consultez les liens suivants :
Comment vérifier le mot de passe
- Une touche spéciale * est utilisée pour réinitialiser le mot de passe.
- Une touche spéciale # est utilisée pour terminer la saisie du mot de passe.
- Chaque touche saisie, à l'exception de * et #, est ajoutée à une chaîne.
- Lorsque la touche # est pressée, la saisie du mot de passe est complète. L'Arduino Nano ESP32 compare la chaîne saisie avec les mots de passe prédéfinis.
- Si le mot de passe saisi est valide, déverrouillez la porte.
Diagramme de câblage
This image is created using Fritzing. Click to enlarge image
Code Arduino Nano ESP32 - Système de verrouillage de porte avec mot de passe utilisant un clavier, serrure électromagnétique
/*
* Ce code Arduino Nano ESP32 a été développé par newbiely.fr
* Ce code Arduino Nano ESP32 est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino-nano-esp32/arduino-nano-esp32-door-lock-system-using-password
*/
#include <Keypad.h>
#define RELAY_PIN D2 // The Arduino Nano ESP32 pin connected to the relay
#define ROW_NUM 4 // keypad four rows
#define COLUMN_NUM 3 // keypad three columns
char keys[ROW_NUM][COLUMN_NUM] = {
{'1', '2', '3'},
{'4', '5', '6'},
{'7', '8', '9'},
{'*', '0', '#'}
};
byte pin_rows[ROW_NUM] = {D10, D9, D8, D7}; // The Arduino Nano ESP32 pin connected to the row pins
byte pin_column[COLUMN_NUM] = {D6, D5, D4}; // The Arduino Nano ESP32 pin connected to the column pins
Keypad keypad = Keypad( makeKeymap(keys), pin_rows, pin_column, ROW_NUM, COLUMN_NUM );
const String password_1 = "1234"; // change your password here
const String password_2 = "4444"; // change your password here
const String password_3 = "55555"; // change your password here
String input_password;
void setup() {
Serial.begin(9600);
input_password.reserve(32); // maximum input characters is 32
pinMode(RELAY_PIN, OUTPUT);
digitalWrite(RELAY_PIN, HIGH); // lock the door
}
void loop() {
char key = keypad.getKey();
if (key) {
Serial.println(key);
if (key == '*') {
input_password = ""; // reset the input password
} else if (key == '#') {
if (input_password == password_1 || input_password == password_2 || input_password == password_3) {
Serial.println("Valid Password => unlock the door");
digitalWrite(RELAY_PIN, LOW); // unlock the door for 20 seconds
delay(20000);
digitalWrite(RELAY_PIN, HIGH); // lock the door
} else {
Serial.println("Invalid Password => Try again");
}
input_password = ""; // reset the input password
} else {
input_password += key; // append new character to input password string
}
}
}
Étapes rapides
Pour commencer avec l'Arduino Nano ESP32, suivez ces étapes :
- Si vous êtes nouveau avec l'Arduino Nano ESP32, consultez le tutoriel sur comment configurer l'environnement pour l'Arduino Nano ESP32 dans l'Arduino IDE.
- Câblez les composants selon le schéma fourni.
- Connectez la carte Arduino Nano ESP32 à votre ordinateur à l'aide d'un câble USB.
- Lancez l'Arduino IDE sur votre ordinateur.
- Sélectionnez la carte Arduino Nano ESP32 et le port COM correspondant.
- Cliquez sur l'icône Librairies dans la barre latérale gauche de l'Arduino IDE.
- Tapez "keypad" dans la boîte de recherche, puis recherchez la bibliothèque keypad de Mark Stanley, Alexander Brevig.
- Cliquez sur le bouton Install pour installer la bibliothèque keypad.
- Copiez le code ci-dessus et collez-le dans l'IDE Arduino.
- Compilez et téléchargez le code sur la carte Arduino Nano ESP32 en cliquant sur le bouton Upload de l'IDE Arduino.
- Pour simuler la serrure électromagnétique installée sur la porte, placez l'électroaimant près de la plaque d'armature.
- Appuyez sur les touches 1111 puis sur #.
- Vérifiez la force d'attraction entre l'électroaimant et la plaque d'armature.
- Appuyez sur les touches 1234 puis sur #.
- Vérifiez la force d'attraction entre l'électroaimant et la plaque d'armature.
- Consultez le résultat sur le moniteur série.
COM6
Invalid Password => Try again
Valid Password => unlock the door
Autoscroll
Clear output
9600 baud
Newline
Code Arduino Nano ESP32 - Système de verrouillage de porte avec mot de passe utilisant un clavier, un verrou électromagnétique et un écran LCD
Le code ci-dessous a ajouté un LCD I2C pour afficher le statut d'accès. Pour le câblage avec l'écran LCD, vous pouvez consulter ce tutoriel Esp32 - Tutoriel LCD I2C
/*
* Ce code Arduino Nano ESP32 a été développé par newbiely.fr
* Ce code Arduino Nano ESP32 est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino-nano-esp32/arduino-nano-esp32-door-lock-system-using-password
*/
#include <LiquidCrystal_I2C.h>
#include <Keypad.h>
#define RELAY_PIN D2 // The Arduino Nano ESP32 pin connected to the relay
#define ROW_NUM 4 // keypad four rows
#define COLUMN_NUM 3 // keypad three columns
char keys[ROW_NUM][COLUMN_NUM] = {
{'1', '2', '3'},
{'4', '5', '6'},
{'7', '8', '9'},
{'*', '0', '#'}
};
byte pin_rows[ROW_NUM] = {D10, D9, D8, D7}; // The Arduino Nano ESP32 pin connected to the row pins
byte pin_column[COLUMN_NUM] = {D6, D5, D4}; // The Arduino Nano ESP32 pin connected to the column pins
Keypad keypad = Keypad( makeKeymap(keys), pin_rows, pin_column, ROW_NUM, COLUMN_NUM );
const String password_1 = "1234"; // change your password here
const String password_2 = "4444"; // change your password here
const String password_3 = "55555"; // change your password here
String input_password;
LiquidCrystal_I2C lcd(0x27, 16, 2); // I2C address 0x27 (from DIYables LCD), 16 column and 2 rows
void setup() {
Serial.begin(9600);
input_password.reserve(32); // maximum input characters is 32
pinMode(RELAY_PIN, OUTPUT);
digitalWrite(RELAY_PIN, HIGH);
lcd.init(); // initialize the lcd
lcd.backlight();
}
void loop() {
char key = keypad.getKey();
if (key) {
Serial.println(key);
if (key == '*') {
input_password = ""; // reset the input password
lcd.clear();
} else if (key == '#') {
lcd.clear();
if (input_password == password_1 || input_password == password_2 || input_password == password_3) {
Serial.println("Valid Password => unlock the door");
lcd.setCursor(0, 0);
lcd.print("CORRECT!");
lcd.setCursor(0, 1);
lcd.print("DOOR UNLOCKED!");
digitalWrite(RELAY_PIN, LOW); // unlock the door for 20 seconds
delay(20000);
digitalWrite(RELAY_PIN, HIGH); // lock the door
} else {
Serial.println("Invalid Password => Try again");
lcd.setCursor(0, 0);
lcd.print("INCORRECT!");
lcd.setCursor(0, 1);
lcd.print("ACCESS DENIED!");
}
input_password = ""; // reset the input password
} else {
if (input_password.length() == 0) {
lcd.clear();
}
input_password += key; // append new character to input password string
lcd.setCursor(input_password.length(), 0); // move cursor to new position
lcd.print('*'); // print * key as hiden character
}
}
}
※ NOTE THAT:
L'adresse I2C de l'écran LCD peut varier selon les fabricants. Dans le code, nous avons utilisé l'adresse 0x27 spécifiée par le fabricant DIYables.