Arduino Nano ESP32 - Bouton - Pression Longue Pression Courte
Ce tutoriel fournit des instructions sur comment utiliser l'Arduino Nano ESP32 pour détecter les appuis longs et courts. En détail, nous apprendrons :
- Comment détecter l'appui court sur le bouton
- Comment détecter l'appui long sur le bouton
- Comment détecter à la fois l'appui long et l'appui court
Préparation du matériel
Or you can buy the following sensor kits:
| 1 | × | DIYables Sensor Kit (30 sensors/displays) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgation : Certains des liens fournis dans cette section sont des liens affiliés Amazon. Nous pouvons recevoir une commission pour tout achat effectué via ces liens, sans coût supplémentaire pour vous. Nous vous remercions de votre soutien.
À propos du bouton
Nous disposons de tutoriels spécifiques sur le bouton. Chaque tutoriel contient des informations détaillées et des instructions étape par étape sur le brochage du matériel, le principe de fonctionnement, la connexion de câblage à l'ESP32, le code Arduino Nano ESP32... Pour en savoir plus, consultez les liens suivants :
Diagramme de câblage
This image is created using Fritzing. Click to enlarge image
Ce tutoriel utilisera la résistance de pull-up interne. L'état du bouton est HIGH lorsqu'il est en position normale et LOW lorsqu'il est pressé.
Comment détecter une pression courte
- Mesurez le temps entre les événements appuyé et relâché.
- Si la durée est plus courte qu'un temps prédéfini, l'événement de pression courte est détecté.
Voyons étape par étape :
- Définissez la durée maximale d'une pression courte.
#define SHORT_PRESS_TIME 500 // 500 millisecondes
- Détectez que le bouton est pressé et enregistrez l'heure de pression.
if(prev_state == HIGH && button_state == LOW)
pressed_time = millis();
- Détectez que le bouton est relâché et enregistrez l'heure de relâchement.
if(prev_state == LOW && button_state == HIGH)
released_time = millis();
- Calculez la durée de pression et
long press_duration = released_time - pressed_time;
- Déterminez l'appui court en comparant la durée de l'appui avec le temps défini pour un appui court.
if( press_duration < SHORT_PRESS_TIME )
Serial.println("A short press is detected");
Code Arduino Nano ESP32 pour détecter les pressions courtes
/*
* Ce code Arduino Nano ESP32 a été développé par newbiely.fr
* Ce code Arduino Nano ESP32 est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino-nano-esp32/arduino-nano-esp32-button-long-press-short-press
*/
#define BUTTON_PIN D2 // Arduino Nano ESP32 pin D2 pin connected to button
#define SHORT_PRESS_TIME 500 // 500 milliseconds
int prev_button_state = LOW; // The previous state from the input pin
int button_state; // The current reading from the input pin
unsigned long pressed_time = 0;
unsigned long released_time = 0;
void setup() {
Serial.begin(9600);
pinMode(BUTTON_PIN, INPUT_PULLUP);
}
void loop() {
// read the state of the switch/button:
button_state = digitalRead(BUTTON_PIN);
if (prev_button_state == HIGH && button_state == LOW) // button is pressed
pressed_time = millis();
else if (prev_button_state == LOW && button_state == HIGH) { // button is released
released_time = millis();
long press_duration = released_time - pressed_time;
if ( press_duration < SHORT_PRESS_TIME )
Serial.println("A short press is detected");
}
// save the the last state
prev_button_state = button_state;
}
Étapes rapides
- Si c'est la première fois que vous utilisez l'Arduino Nano ESP32, consultez comment configurer l'environnement pour Arduino Nano ESP32 sur Arduino IDE.
- Téléversez le code ci-dessus sur l'Arduino Nano ESP32 via l'Arduino IDE.
- Appuyez brièvement sur le bouton plusieurs fois.
- Consultez le résultat sur le moniteur série. Cela ressemble à ce qui suit :
COM6
A short press is detected
Autoscroll
Clear output
9600 baud
Newline
※ NOTE THAT:
Le moniteur série peut enregistrer plusieurs pressions courtes pour une seule pression. C'est un comportement normal du bouton. Ce comportement est appelé le « phénomène de rebond ». Nous apprendrons comment éliminer ce problème plus tard dans ce tutoriel.
Comment détecter une pression longue
Il existe deux cas d'utilisation pour détecter l'appui long.
- L'événement de longue pression est détecté juste après que le bouton soit relâché.
- L'événement de longue pression est détecté pendant que le bouton est enfoncé.
Dans le premier cas :
- Mesurez la durée entre l'événement de pression et l'événement de relâchement.
- Si la durée est supérieure à un temps pré-défini, l'événement de longue pression est détecté.
Dans le deuxième cas : pendant la durée où le bouton est pressé, répétez le processus suivant :
- Mesurez le temps de pression.
- Si la durée est plus longue que le temps prédéfini, l'événement de pression longue est détecté.
- Sinon, répétez le processus jusqu'à ce que le bouton soit relâché.
Code Arduino Nano ESP32 pour détecter l'appui long lors du relâchement
/*
* Ce code Arduino Nano ESP32 a été développé par newbiely.fr
* Ce code Arduino Nano ESP32 est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino-nano-esp32/arduino-nano-esp32-button-long-press-short-press
*/
#define BUTTON_PIN D2 // Arduino Nano ESP32 pin D2 pin connected to button
#define LONG_PRESS_TIME 1000 // 1000 milliseconds
int prev_button_state = LOW; // The previous state from the input pin
int button_state; // The current reading from the input pin
unsigned long pressed_time = 0;
unsigned long released_time = 0;
void setup() {
Serial.begin(9600);
pinMode(BUTTON_PIN, INPUT_PULLUP);
}
void loop() {
// read the state of the switch/button:
button_state = digitalRead(BUTTON_PIN);
if(prev_button_state == HIGH && button_state == LOW) // button is pressed
pressed_time = millis();
else if(prev_button_state == LOW && button_state == HIGH) { // button is released
released_time = millis();
long press_duration = released_time - pressed_time;
if( press_duration > LONG_PRESS_TIME )
Serial.println("A long press is detected");
}
// save the the last state
prev_button_state = button_state;
}
Étapes rapides
- Si c’est la première fois que vous utilisez un Arduino Nano ESP32, consultez comment configurer l'environnement pour Arduino Nano ESP32 sur Arduino IDE.
- Téléversez le code ci-dessus sur Arduino Nano ESP32 via Arduino IDE.
- Appuyez et relâchez le bouton après une seconde.
- Vérifiez le résultat sur le moniteur série. Cela ressemble à ce qui suit :
COM6
A long press is detected
Autoscroll
Clear output
9600 baud
Newline
Code Arduino Nano ESP32 pour détecter une pression longue pendant l'appui
/*
* Ce code Arduino Nano ESP32 a été développé par newbiely.fr
* Ce code Arduino Nano ESP32 est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino-nano-esp32/arduino-nano-esp32-button-long-press-short-press
*/
#define BUTTON_PIN D2 // Arduino Nano ESP32 pin D2 pin connected to button
#define LONG_PRESS_TIME 1000 // 1000 milliseconds
int prev_button_state = LOW; // The previous state from the input pin
int button_state; // The current reading from the input pin
unsigned long pressed_time = 0;
bool is_pressing = false;
bool is_long_detected = false;
void setup() {
Serial.begin(9600);
pinMode(BUTTON_PIN, INPUT_PULLUP);
}
void loop() {
// read the state of the switch/button:
button_state = digitalRead(BUTTON_PIN);
if(prev_button_state == HIGH && button_state == LOW) { // button is pressed
pressed_time = millis();
is_pressing = true;
is_long_detected = false;
} else if(prev_button_state == LOW && button_state == HIGH) { // button is released
is_pressing = false;
}
if(is_pressing == true && is_long_detected == false) {
long press_duration = millis() - pressed_time;
if( press_duration > LONG_PRESS_TIME ) {
Serial.println("A long press is detected");
is_long_detected = true;
}
}
// save the the last state
prev_button_state = button_state;
}
Étapes rapides
- Si c'est la première fois que vous utilisez un Arduino Nano ESP32, consultez comment configurer l'environnement pour Arduino Nano ESP32 sur Arduino IDE.
- Téléversez le code ci-dessus vers Arduino Nano ESP32 via l'Arduino IDE.
- Appuyez et relâchez le bouton après plusieurs secondes.
- Consultez le résultat sur le moniteur série. Cela ressemble à ce qui suit :
COM6
A long press is detected
Autoscroll
Clear output
9600 baud
Newline
Comment détecter à la fois les appuis longs et les appuis courts
Appui court et appui long après relâchement
/*
* Ce code Arduino Nano ESP32 a été développé par newbiely.fr
* Ce code Arduino Nano ESP32 est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino-nano-esp32/arduino-nano-esp32-button-long-press-short-press
*/
#define BUTTON_PIN D2 // Arduino Nano ESP32 pin D2 pin connected to button
#define SHORT_PRESS_TIME 1000 // 1000 milliseconds
#define LONG_PRESS_TIME 1000 // 1000 milliseconds
int prev_button_state = LOW; // The previous state from the input pin
int button_state; // The current reading from the input pin
unsigned long pressed_time = 0;
unsigned long released_time = 0;
void setup() {
Serial.begin(9600);
pinMode(BUTTON_PIN, INPUT_PULLUP);
}
void loop() {
// read the state of the switch/button:
button_state = digitalRead(BUTTON_PIN);
if (prev_button_state == HIGH && button_state == LOW) // button is pressed
pressed_time = millis();
else if (prev_button_state == LOW && button_state == HIGH) { // button is released
released_time = millis();
long press_duration = released_time - pressed_time;
if ( press_duration < SHORT_PRESS_TIME )
Serial.println("A short press is detected");
if ( press_duration > LONG_PRESS_TIME )
Serial.println("A long press is detected");
}
// save the the last state
prev_button_state = button_state;
}
Étapes rapides
- Si c'est la première fois que vous utilisez l'Arduino Nano ESP32, consultez comment configurer l'environnement pour Arduino Nano ESP32 sur Arduino IDE.
- Téléversez le code ci-dessus sur l'Arduino Nano ESP32 via l'Arduino IDE.
- Appuyez longuement et brièvement sur le bouton.
- Consultez le résultat sur le moniteur série. Cela ressemble à ce qui suit :
※ NOTE THAT:
Le moniteur série peut afficher plusieurs détections d'appui court lors d'un appui long. C'est le comportement normal du bouton. Ce comportement est appelé le « phénomène de rebond ». Le problème sera résolu dans la dernière partie de ce tutoriel.
Pression courte et pression longue pendant l'appui
/*
* Ce code Arduino Nano ESP32 a été développé par newbiely.fr
* Ce code Arduino Nano ESP32 est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino-nano-esp32/arduino-nano-esp32-button-long-press-short-press
*/
#define BUTTON_PIN D2 // Arduino Nano ESP32 pin D2 pin connected to button
#define SHORT_PRESS_TIME 1000 // 1000 milliseconds
#define LONG_PRESS_TIME 1000 // 1000 milliseconds
int prev_button_state = LOW; // The previous state from the input pin
int button_state; // The current reading from the input pin
unsigned long pressed_time = 0;
unsigned long released_time = 0;
bool is_pressing = false;
bool is_long_detected = false;
void setup() {
Serial.begin(9600);
pinMode(BUTTON_PIN, INPUT_PULLUP);
}
void loop() {
// read the state of the switch/button:
button_state = digitalRead(BUTTON_PIN);
if (prev_button_state == HIGH && button_state == LOW) { // button is pressed
pressed_time = millis();
is_pressing = true;
is_long_detected = false;
} else if (prev_button_state == LOW && button_state == HIGH) { // button is released
is_pressing = false;
released_time = millis();
long press_duration = released_time - pressed_time;
if ( press_duration < SHORT_PRESS_TIME )
Serial.println("A short press is detected");
}
if (is_pressing == true && is_long_detected == false) {
long press_duration = millis() - pressed_time;
if ( press_duration > LONG_PRESS_TIME ) {
Serial.println("A long press is detected");
is_long_detected = true;
}
}
// save the the last state
prev_button_state = button_state;
}
Étapes rapides
- Si c'est la première fois que vous utilisez l'Arduino Nano ESP32, consultez comment configurer l'environnement pour Arduino Nano ESP32 sur Arduino IDE.
- Téléversez le code ci-dessus sur Arduino Nano ESP32 via Arduino IDE
- Appuyez longuement et brièvement sur le bouton.
- Consultez le résultat sur le moniteur série. Cela ressemble à ce qui suit :
Appui long et appui court avec anti-rebond
Il est très important de "debouncer" le bouton dans de nombreuses applications.
Le debounce est un peu compliqué, surtout lorsqu'on utilise plusieurs boutons. Pour simplifier les choses pour les débutants, nous avons créé une bibliothèque, appelée ezButton.
Nous utiliserons cette bibliothèque dans les codes ci-dessous.
Appui court et appui long avec anti-rebond après relâchement
/*
* Ce code Arduino Nano ESP32 a été développé par newbiely.fr
* Ce code Arduino Nano ESP32 est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino-nano-esp32/arduino-nano-esp32-button-long-press-short-press
*/
#include <ezButton.h>
#define SHORT_PRESS_TIME 1000 // 1000 milliseconds
#define LONG_PRESS_TIME 1000 // 1000 milliseconds
ezButton button(D2); // create ezButton object for pin Arduino Nano ESP32 pin D2
unsigned long pressed_time = 0;
unsigned long released_time = 0;
void setup() {
Serial.begin(9600);
button.setDebounceTime(50); // set debounce time to 50 milliseconds
}
void loop() {
button.loop(); // MUST call the loop() function first
if (button.isPressed())
pressed_time = millis();
if (button.isReleased()) {
released_time = millis();
long press_duration = released_time - pressed_time;
if ( press_duration < SHORT_PRESS_TIME )
Serial.println("A short press is detected");
if ( press_duration > LONG_PRESS_TIME )
Serial.println("A long press is detected");
}
}
Étapes rapides
- Si c'est la première fois que vous utilisez l'Arduino Nano ESP32, consultez comment configurer l'environnement pour l'Arduino Nano ESP32 sur Arduino IDE.
- Installez la bibliothèque ezButton. Voir Comment faire
- Téléversez le code ci-dessus sur l'Arduino Nano ESP32 via Arduino IDE
- Appuyez longuement et brièvement sur le bouton.
- Consultez le résultat sur le moniteur série. Cela ressemble à ce qui suit :
Appui court et appui long avec anti-rebond pendant l'appui
/*
* Ce code Arduino Nano ESP32 a été développé par newbiely.fr
* Ce code Arduino Nano ESP32 est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/arduino-nano-esp32/arduino-nano-esp32-button-long-press-short-press
*/
#include <ezButton.h>
#define SHORT_PRESS_TIME 1000 // 1000 milliseconds
#define LONG_PRESS_TIME 1000 // 1000 milliseconds
ezButton button(D2); // create ezButton object for pin Arduino Nano ESP32 pin D2
unsigned long pressed_time = 0;
unsigned long released_time = 0;
bool is_pressing = false;
bool is_long_detected = false;
void setup() {
Serial.begin(9600);
button.setDebounceTime(50); // set debounce time to 50 milliseconds
}
void loop() {
button.loop(); // MUST call the loop() function first
if (button.isPressed()) {
pressed_time = millis();
is_pressing = true;
is_long_detected = false;
}
if (button.isReleased()) {
is_pressing = false;
released_time = millis();
long press_duration = released_time - pressed_time;
if ( press_duration < SHORT_PRESS_TIME )
Serial.println("A short press is detected");
}
if (is_pressing == true && is_long_detected == false) {
long press_duration = millis() - pressed_time;
if ( press_duration > LONG_PRESS_TIME ) {
Serial.println("A long press is detected");
is_long_detected = true;
}
}
}
Étapes rapides
- Si c'est la première fois que vous utilisez un Arduino Nano ESP32, consultez comment configurer l'environnement pour Arduino Nano ESP32 sur Arduino IDE.
- Installez la bibliothèque ezButton. Voir Comment faire
- Téléversez le code ci-dessus sur Arduino Nano ESP32 via Arduino IDE
- Appuyez longuement et brièvement sur le bouton.
- Vérifiez le résultat sur le moniteur série. Cela ressemble à ce qui suit :
Vidéo
Pourquoi a-t-on besoin d'une pression longue et d'une pression courte ?
- Pour économiser le nombre de boutons et de broches d'entrée numérique. Un seul bouton peut conserver deux fonctionnalités ou plus. Par exemple, appuyez brièvement pour allumer la lumière, appuyez longuement pour allumer le ventilateur.
- Utilisez l'appui long au lieu de l'appui court pour éviter les pressions accidentelles. Par exemple, certains types d'appareils utilisent le bouton pour la réinitialisation d'usine. Si le bouton est pressé par accident, c'est dangereux.