ESP8266 - Interrupteur de fin de course pour moteur pas à pas
Ce tutoriel vous explique comment utiliser l'ESP8266 pour contrôler un moteur pas à pas via un interrupteur de fin de course et un pilote L298N. Plus précisément, nous aborderons :
- Comment programmer l'ESP8266 pour arrêter le moteur pas à pas lorsque l'interrupteur de fin de course est actionné.
- Comment programmer l'ESP8266 pour changer la direction du moteur pas à pas lorsque l'interrupteur de fin de course est actionné.
- Comment programmer l'ESP8266 pour changer la direction du moteur pas à pas avec deux interrupteurs de fin de course installés en positions opposées.
Préparation du matériel
Or you can buy the following sensor kits:
| 1 | × | DIYables Sensor Kit (30 sensors/displays) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgation : Certains des liens fournis dans cette section sont des liens affiliés Amazon. Nous pouvons recevoir une commission pour tout achat effectué via ces liens, sans coût supplémentaire pour vous. Nous vous remercions de votre soutien.
À propos du moteur pas à pas et de l'interrupteur de fin de course
Si vous n'êtes pas familiarisé avec le moteur pas à pas et l'interrupteur de fin de course (y compris le brochage, le fonctionnement, la programmation, etc.), les tutoriels suivants peuvent vous fournir davantage d'informations :
- ESP8266 - Interrupteur de limite. tutorial
- ESP8266 - Moteur pas à pas. tutorial
Diagramme de câblage
Ce tutoriel fournit le schéma de câblage pour deux cas : un moteur pas à pas + un interrupteur de fin de course, un moteur pas à pas + deux interrupteurs de fin de course.
- Schéma de câblage entre ESP8266, moteur pas à pas et un interrupteur de fin de course.
This image is created using Fritzing. Click to enlarge image
Voir plus dans Brochage ESP8266. et Comment alimenter l'ESP8266..
- Schéma de câblage entre l'ESP8266, le moteur pas à pas et deux interrupteurs de fin de course.
This image is created using Fritzing. Click to enlarge image
※ Note:
La connexion des câbles entre le moteur pas à pas et le L298N peut varier selon le type de moteur pas à pas. Par conséquent, il est important de consulter ce tutoriel ESP8266 - Moteur pas à pas. pour comprendre comment réaliser la connexion.
Code ESP8266 - Arrêter un moteur pas à pas avec un interrupteur de fin de course
Il existe diverses méthodes pour arrêter un moteur pas à pas :
- Invokez la fonction stepper.stop() : Cela ne provoquera pas un arrêt instantané, mais plutôt un arrêt progressif.
- Omettez d'appeler la fonction stepper.run() : Cela entraînera un arrêt immédiat du moteur pas à pas.
Le code ci-dessous entraînera la rotation continue d'un moteur pas à pas jusqu'à ce qu'un interrupteur de fin de course soit actionné, moment auquel il s'arrêtera immédiatement.
/*
* Ce code ESP8266 NodeMCU a été développé par newbiely.fr
* Ce code ESP8266 NodeMCU est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/esp8266/esp8266-stepper-motor-limit-switch
*/
#include <ezButton.h>
#include <AccelStepper.h>
#define MAX_POSITION 0x7FFFFFFF // maximum of position we can set (long type)
ezButton limit_switch(D0); // create ezButton object that attach to the ESP8266 pin D0
AccelStepper stepper(AccelStepper::FULL4WIRE, D1, D2, D5, D6);
bool is_stopped = false;
void setup() {
Serial.begin(9600);
limit_switch.setDebounceTime(50); // set debounce time to 50 milliseconds
stepper.setMaxSpeed(500.0); // set the maximum speed
stepper.setAcceleration(50.0); // set acceleration
stepper.setSpeed(100); // set initial speed
stepper.setCurrentPosition(0); // set position
stepper.moveTo(MAX_POSITION);
}
void loop() {
limit_switch.loop(); // MUST call the loop() function first
if (limit_switch.isPressed()) {
Serial.println(F("The limit switch: TOUCHED"));
is_stopped = true;
}
if (is_stopped == false) {
// without this part, the move will stop after reaching maximum position
if (stepper.distanceToGo() == 0) { // if motor moved to the maximum position
stepper.setCurrentPosition(0); // reset position to 0
stepper.moveTo(MAX_POSITION); // move the motor to maximum position again
}
stepper.run(); // MUST be called in loop() function
} else {
// If the stepper.run() function is not invoked, the motor stops immediately
// NOTE: invoking the stepper.stop() does NOT stop the motor immediately.
Serial.println(F("The stepper motor is STOPPED"));
}
}
Étapes rapides
Pour commencer avec l'ESP8266 sur Arduino IDE, suivez ces étapes :
- Consultez le tutoriel Installation du logiciel ESP8266. si c'est la première fois que vous utilisez ESP8266.
- Câblez les composants comme indiqué dans le schéma.
- Connectez la carte ESP8266 à votre ordinateur à l'aide d'un câble USB.
- Ouvrez Arduino IDE sur votre ordinateur.
- Sélectionnez la bonne carte ESP8266, comme (par exemple NodeMCU 1.0 (Module ESP-12E)), et son port COM respectif.
- Connectez un câble USB entre l'ESP8266 et le PC.
- Ouvrez Arduino IDE, sélectionnez la carte et le port appropriés.
- Cliquez sur l'icône Libraries dans la barre latérale gauche de l'Arduino IDE.
- Recherchez "ezButton", puis localisez la bibliothèque de boutons fournie par ArduinoGetStarted.com.
- Appuyez sur le bouton Install pour installer la bibliothèque ezButton.
- Recherchez « AccelStepper » et localisez la bibliothèque AccelStepper créée par Mike McCauley.
- Appuyez sur le bouton Install pour ajouter la bibliothèque AccelStepper.
- Copiez le code et ouvrez-le avec l'IDE Arduino.
- Cliquez sur le bouton Upload afin de transférer le code vers l'ESP8266.
- Si le câblage est correctement effectué, le moteur tournera dans le sens horaire.
- Appuyez sur l'interrupteur de fin de course et le moteur s'arrêtera immédiatement.
- Le résultat qui apparaît sur le Moniteur Série devrait ressembler à ceci.
COM6
The limit switch: TOUCHED
The stepper motor is STOPPED
The stepper motor is STOPPED
The stepper motor is STOPPED
The stepper motor is STOPPED
Autoscroll
Clear output
9600 baud
Newline
Explication du code
Découvrez l'explication ligne par ligne contenue dans les commentaires du code source !
Code ESP8266 - Changer la direction d'un moteur pas à pas par un interrupteur de fin de course.
Le code ci-dessous permet à un moteur pas à pas de tourner en continu, et il inversera sa direction lorsqu'un interrupteur de fin de course sera touché.
/*
* Ce code ESP8266 NodeMCU a été développé par newbiely.fr
* Ce code ESP8266 NodeMCU est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/esp8266/esp8266-stepper-motor-limit-switch
*/
#include <ezButton.h>
#include <AccelStepper.h>
#define DIRECTION_CCW -1
#define DIRECTION_CW 1
#define MAX_POSITION 0x7FFFFFFF // maximum of position we can set (long type)
ezButton limit_switch(D0); // create ezButton object that attach to the ESP8266 pin D0
AccelStepper stepper(AccelStepper::FULL4WIRE, D1, D2, D5, D6);
int direction = DIRECTION_CW;
long target_pos = 0;
void setup() {
Serial.begin(9600);
limit_switch.setDebounceTime(50); // set debounce time to 50 milliseconds
stepper.setMaxSpeed(500.0); // set the maximum speed
stepper.setAcceleration(50.0); // set acceleration
stepper.setSpeed(100); // set initial speed
stepper.setCurrentPosition(0); // set position
target_pos = direction * MAX_POSITION;
stepper.moveTo(target_pos);
}
void loop() {
limit_switch.loop(); // MUST call the loop() function first
if (limit_switch.isPressed()) {
Serial.println(F("The limit switch: TOUCHED"));
direction *= -1; // change direction
Serial.print(F("The direction -> "));
if (direction == DIRECTION_CW)
Serial.println(F("CLOCKWISE"));
else
Serial.println(F("ANTI-CLOCKWISE"));
target_pos = direction * MAX_POSITION;
stepper.setCurrentPosition(0); // set position
stepper.moveTo(target_pos);
}
// without this part, the move will stop after reaching maximum position
if (stepper.distanceToGo() == 0) { // if motor moved to the maximum position
stepper.setCurrentPosition(0); // reset position to 0
stepper.moveTo(target_pos); // move the motor to maximum position again
}
stepper.run(); // MUST be called in loop() function
}
Étapes rapides
Pour commencer avec l'ESP8266 sur Arduino IDE, suivez ces étapes :
- Consultez le tutoriel Installation du logiciel ESP8266. si c'est votre première utilisation de l'ESP8266.
- Câblez les composants comme indiqué dans le schéma.
- Connectez la carte ESP8266 à votre ordinateur à l'aide d'un câble USB.
- Ouvrez Arduino IDE sur votre ordinateur.
- Choisissez la bonne carte ESP8266, telle que (par exemple, NodeMCU 1.0 (Module ESP-12E)), et son port COM respectif.
- Copiez le code et ouvrez-le avec Arduino IDE.
- Cliquez sur le bouton Upload pour envoyer le code à l'ESP8266.
- Si le câblage est correct, le moteur tournera dans le sens des aiguilles d'une montre.
- Lorsque vous touchez l'interrupteur de fin de course, la rotation du moteur pas à pas sera inversée dans le sens antihoraire.
- Toucher de nouveau l'interrupteur de fin de course provoquera la rotation du moteur pas à pas dans le sens des aiguilles d'une montre.
- Le résultat sur le moniteur série devrait ressembler à ceci.
COM6
The limit switch: TOUCHED
The direction -> ANTI-CLOCKWISE
The limit switch: TOUCHED
The direction -> CLOCKWISE
Autoscroll
Clear output
9600 baud
Newline
Code ESP8266 - Changer la direction du moteur pas à pas avec deux interrupteurs de fin de course
Le code ci-dessous entraîne la rotation continue d'un moteur pas à pas, et il inversera sa direction lorsque l'un des deux interrupteurs de limite est touché.
/*
* Ce code ESP8266 NodeMCU a été développé par newbiely.fr
* Ce code ESP8266 NodeMCU est mis à disposition du public sans aucune restriction.
* Pour des instructions complètes et des schémas de câblage, veuillez visiter:
* https://newbiely.fr/tutorials/esp8266/esp8266-stepper-motor-limit-switch
*/
#include <ezButton.h>
#include <AccelStepper.h>
#define DIRECTION_CCW -1
#define DIRECTION_CW 1
#define STATE_CHANGE_DIR 1
#define STATE_MOVE 2
#define STATE_MOVING 3
#define MAX_POSITION 0x7FFFFFFF // maximum of position we can set (long type)
ezButton limit_switch_1(D0); // create ezButton object that attach to the ESP8266 pin D0
ezButton limit_switch_2(D8); // create ezButton object that attach to the ESP8266 pin D8
AccelStepper stepper(AccelStepper::FULL4WIRE, D1, D2, D5, D6);
int stepper_state = STATE_MOVE;
int direction = DIRECTION_CW;
long target_pos = 0;
void setup() {
Serial.begin(9600);
limit_switch_1.setDebounceTime(50); // set debounce time to 50 milliseconds
limit_switch_2.setDebounceTime(50); // set debounce time to 50 milliseconds
stepper.setMaxSpeed(500.0); // set the maximum speed
stepper.setAcceleration(50.0); // set acceleration
stepper.setSpeed(100); // set initial speed
stepper.setCurrentPosition(0); // set position
}
void loop() {
limit_switch_1.loop(); // MUST call the loop() function first
limit_switch_2.loop(); // MUST call the loop() function first
if (limit_switch_1.isPressed()) {
stepper_state = STATE_CHANGE_DIR;
Serial.println(F("The limit switch 1: TOUCHED"));
}
if (limit_switch_2.isPressed()) {
stepper_state = STATE_CHANGE_DIR;
Serial.println(F("The limit switch 2: TOUCHED"));
}
switch (stepper_state) {
case STATE_CHANGE_DIR:
direction *= -1; // change direction
Serial.print(F("The direction -> "));
if (direction == DIRECTION_CW)
Serial.println(F("CLOCKWISE"));
else
Serial.println(F("ANTI-CLOCKWISE"));
stepper_state = STATE_MOVE; // after changing direction, go to the next state to move the motor
break;
case STATE_MOVE:
target_pos = direction * MAX_POSITION;
stepper.setCurrentPosition(0); // set position
stepper.moveTo(target_pos);
stepper_state = STATE_MOVING; // after moving, go to the next state to keep the motor moving infinity
break;
case STATE_MOVING: // without this state, the move will stop after reaching maximum position
if (stepper.distanceToGo() == 0) { // if motor moved to the maximum position
stepper.setCurrentPosition(0); // reset position to 0
stepper.moveTo(target_pos); // move the motor to maximum position again
}
break;
}
stepper.run(); // MUST be called in loop() function
}
Étapes rapides
- Câblez les composants comme indiqué dans le schéma.
- Connectez la carte ESP8266 à votre ordinateur à l'aide d'un câble USB.
- Ouvrez Arduino IDE sur votre ordinateur.
- Choisissez la bonne carte ESP8266, comme (par exemple, NodeMCU 1.0 (Module ESP-12E)), et son port COM respectif.
- Copiez le code et ouvrez-le avec Arduino IDE.
- Cliquez sur le bouton Upload dans l'IDE pour téléverser le code sur l'ESP8266.
- Si le câblage est correct, le moteur devrait tourner dans le sens des aiguilles d'une montre.
- Lorsque vous touchez l'interrupteur de limite 1, la direction du moteur pas à pas devrait passer en sens antihoraire.
- Toucher l'interrupteur de limite 2 devrait faire inverser à nouveau la direction du moteur, cette fois en sens horaire.
- Le résultat affiché sur le moniteur série devrait ressembler à ce qui suit.
COM6
The limit switch 1: TOUCHED
The direction -> ANTI-CLOCKWISE
The limit switch 2: TOUCHED
The direction -> CLOCKWISE
Autoscroll
Clear output
9600 baud
Newline